hlmod.hu :: Több újraéledési hely

hlmod.hu https://hlmod.hu/

Több újraéledési hely https://hlmod.hu/viewtopic.php?f=101&t=12669	Oldal: 1 / 1

Szerző:

norbee.16 [ 2013.06.10. 21:27 ]

Hozzászólás témája:

Több újraéledési hely

Plugin Neve:	Több újraéledési hely	Plugint készitette:	xPaw
Játék:	Mind	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Több Újraéledési hely - Bad Spawn Spreventer

/*Leírás*\
A plugin lényege az hogy, egy vagy több pályán nincs elég spawn (újraéledési) hely akkor ez a plugin létrehoz 32 player (játékos)nak elegendő spawn (újraéledési) helyet.

/*Cvarok*\
Nincsenek!

/*Telepités*\
badspawnspreventer.amxx -> plugins mappába
badspawnspreventer.sma -> scripting mappába (Hanyagolható)

Jó Játékot hozá

#include < amxmodx >
#include < engine >
#include < hamsandwich >

new HamHook:g_iFwdTakeDamage, bool:g_bHamHookEnabled;

new const Float:g_flMoves[ ][ 3 ] = { // Credits to Ramono
	{0.0, 0.0, 1.0}, {0.0, 0.0, -1.0}, {0.0, 1.0, 0.0}, {0.0, -1.0, 0.0}, {1.0, 0.0, 0.0}, {-1.0, 0.0, 0.0}, {-1.0, 1.0, 1.0}, {1.0, 1.0, 1.0}, {1.0, -1.0, 1.0}, {1.0, 1.0, -1.0}, {-1.0, -1.0, 1.0}, {1.0, -1.0, -1.0}, {-1.0, 1.0, -1.0}, {-1.0, -1.0, -1.0},
	{0.0, 0.0, 2.0}, {0.0, 0.0, -2.0}, {0.0, 2.0, 0.0}, {0.0, -2.0, 0.0}, {2.0, 0.0, 0.0}, {-2.0, 0.0, 0.0}, {-2.0, 2.0, 2.0}, {2.0, 2.0, 2.0}, {2.0, -2.0, 2.0}, {2.0, 2.0, -2.0}, {-2.0, -2.0, 2.0}, {2.0, -2.0, -2.0}, {-2.0, 2.0, -2.0}, {-2.0, -2.0, -2.0},
	{0.0, 0.0, 3.0}, {0.0, 0.0, -3.0}, {0.0, 3.0, 0.0}, {0.0, -3.0, 0.0}, {3.0, 0.0, 0.0}, {-3.0, 0.0, 0.0}, {-3.0, 3.0, 3.0}, {3.0, 3.0, 3.0}, {3.0, -3.0, 3.0}, {3.0, 3.0, -3.0}, {-3.0, -3.0, 3.0}, {3.0, -3.0, -3.0}, {-3.0, 3.0, -3.0}, {-3.0, -3.0, -3.0},
	{0.0, 0.0, 4.0}, {0.0, 0.0, -4.0}, {0.0, 4.0, 0.0}, {0.0, -4.0, 0.0}, {4.0, 0.0, 0.0}, {-4.0, 0.0, 0.0}, {-4.0, 4.0, 4.0}, {4.0, 4.0, 4.0}, {4.0, -4.0, 4.0}, {4.0, 4.0, -4.0}, {-4.0, -4.0, 4.0}, {4.0, -4.0, -4.0}, {-4.0, 4.0, -4.0}, {-4.0, -4.0, -4.0},
	{0.0, 0.0, 5.0}, {0.0, 0.0, -5.0}, {0.0, 5.0, 0.0}, {0.0, -5.0, 0.0}, {5.0, 0.0, 0.0}, {-5.0, 0.0, 0.0}, {-5.0, 5.0, 5.0}, {5.0, 5.0, 5.0}, {5.0, -5.0, 5.0}, {5.0, 5.0, -5.0}, {-5.0, -5.0, 5.0}, {5.0, -5.0, -5.0}, {-5.0, 5.0, -5.0}, {-5.0, -5.0, -5.0}
};

public plugin_init( ) {
	register_plugin( "Bad Spawns Preventer", "1.2", "xPaw" );
	
	RegisterHam( Ham_Spawn, "player", "FwdHamPlayerSpawn_Pre" );
	RegisterHam( Ham_Spawn, "player", "FwdHamPlayerSpawn_Post", 1 );
	
	DisableHamForward( g_iFwdTakeDamage = RegisterHam( Ham_TakeDamage, "player", "FwdHamPlayerDamage" ) );
}

public FwdHamPlayerDamage( const id, const iInflictor, const iAttacker, Float:flDamage, iDamageBits )
	return ( iDamageBits == DMG_GENERIC && iAttacker == 0 && flDamage == 200.0 ) ? HAM_SUPERCEDE : HAM_IGNORED;

public FwdHamPlayerSpawn_Pre( const id ) {
	if( !g_bHamHookEnabled ) {
		EnableHamForward( g_iFwdTakeDamage );
		
		g_bHamHookEnabled = true;
	}
}

public FwdHamPlayerSpawn_Post( const id ) {
	if( g_bHamHookEnabled ) {
		DisableHamForward( g_iFwdTakeDamage );
		
		g_bHamHookEnabled = false;
	}
	
	if( is_user_alive( id ) ) {
		new Float:vOrigin[ 3 ], iFlags = entity_get_int( id, EV_INT_flags );
		entity_get_vector( id, EV_VEC_origin, vOrigin );
		
		if( IsUserStuck( id, vOrigin, iFlags ) ) {
			new Float:vNewOrigin[ 3 ], Float:vMins[ 3 ];
			entity_get_vector( id, EV_VEC_mins, vMins );
			
			for( new i = 0; i < sizeof g_flMoves; i++ ) {
				vNewOrigin[ 0 ] = vOrigin[ 0 ] - vMins[ 0 ] * g_flMoves[ i ][ 0 ];
				vNewOrigin[ 1 ] = vOrigin[ 1 ] - vMins[ 1 ] * g_flMoves[ i ][ 1 ];
				vNewOrigin[ 2 ] = vOrigin[ 2 ] - vMins[ 2 ] * g_flMoves[ i ][ 2 ];
				
				if( !IsUserStuck( id, vNewOrigin, iFlags ) ) {
					entity_set_vector( id, EV_VEC_velocity, Float:{ 0.0, 0.0, 0.0 } );
					entity_set_int( id, EV_INT_flags, iFlags | FL_DUCKING );
					
					entity_set_size( id, Float:{ -16.0, -16.0, -18.0 }, Float:{ 16.0, 16.0, 18.0 } );
					entity_set_origin( id, vNewOrigin );
					
					break;
				}
			}
		}
	}
}

bool:IsUserStuck( const id, const Float:vOrigin[ 3 ], const iFlags )
	return bool:( trace_hull( vOrigin, iFlags & FL_DUCKING ? HULL_HEAD : HULL_HUMAN, id, IGNORE_MONSTERS ) & 2 );

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	DanKe16 [ 2013.06.11. 19:28 ]
Hozzászólás témája:	Re: Több újraéledési hely \| Mind \| Technikai/Fejlesztő
hasznos.. Szép munka! Erre kapsz egy 5-öst:)

Szerző:	norbee.16 [ 2013.06.11. 23:04 ]
Hozzászólás témája:	Re: Több újraéledési hely \| Mind \| Technikai/Fejlesztő
Nm :) Ez màr egy elég régi plugin. Énis ezt használom a zombis szerveremen és edig tökéletesen futtot. ;)

Szerző:	chasper.cfg [ 2013.06.12. 13:43 ]
Hozzászólás témája:	Re: Több újraéledési hely \| Mind \| Technikai/Fejlesztő
Ja én is ezt használom még kiki mondta :D

Szerző:	expert [ 2013.06.13. 06:05 ]
Hozzászólás témája:	Re: Több újraéledési hely \| Mind \| Technikai/Fejlesztő
Nekem de_nuke mappon nem ment vagyis ott nem engedett be 20 játékostól többet beállni specből.

Szerző:	chasper.cfg [ 2013.06.13. 09:20 ]
Hozzászólás témája:	Re: Több újraéledési hely \| Mind \| Technikai/Fejlesztő
#10642 nevermore Már kértem a név változtatást pár éve , és régóta ismerem a plugint! Nem minden konfigos ismeri az "összes plugint"! Legközelebb ha kötekedni szeretnél vagy ha akarsz valamit azt üzenetbe tedd meg! Kössz!

Szerző:	DeteCT0R [ 2013.06.13. 15:06 ]
Hozzászólás témája:	Re: Több újraéledési hely \| Mind \| Technikai/Fejlesztő
Expert pedig a nuke tudtom szerint alapbol 32 jatekosra van :D(Javits ha tevedek)

Szerző:	DeteCT0R [ 2013.06.13. 23:41 ]
Hozzászólás témája:	Re: Több újraéledési hely \| Mind \| Technikai/Fejlesztő
#10652 nevermore Csak itt az oldal es a forum osszevan kotve :)Szoval egy hejen van :) es nem erdemes belepiszkalni :)

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/