hlmod.hu :: Újratöltési hibák Fixálása

hlmod.hu https://hlmod.hu/

Újratöltési hibák Fixálása https://hlmod.hu/viewtopic.php?f=101&t=17581	Oldal: 1 / 1

Szerző:

Z77 [ 2014.10.15. 13:21 ]

Hozzászólás témája:

Újratöltési hibák Fixálása

Plugin Neve:	Újratöltési hibák Fixálása	Plugint készitette:	Numb
Játék:	Counter-Strike	Kategória:	Technikai/Fejlesztő
Eredeti link:	Megnézem	Jóváhagyó:	DeteCT0R

Leírás
Bizonyára, már mindenki látott már olyan jelenséget, hogy megveszitek a Deagle -t, és 7/7 -es a tár, de még is újratölt. Ilyenkor lőni kell egyet, és a bug eltűnik. Nos, evvel a Plug-Inal, fixálhatjuk ezt a bugot.

Szükséges modulok:
FakeMeta
HamSandWich

További információ:
Tesztelve Counter-Strike 1.6 amxmodx 1.8.2 ( Fejlesztői változattal ). Ha tesztelni szeretnéd ezt a hibát, veszel egy automata fegyvert ( MP5, AK47 , M4A1 etc.. ), 2 tartalék tárral, kezdj el lőni, amíg eléred az újratöltést, majd egyszer tölts újra, lőj addig, amíg eléred a 0 lőszert és kezdj újra tölteni - ez az, amikor az animáció hiba történik. Ez a Plug-In kijavítja ezt a hibát.

Figyelem:
Az animációk, kliens oldaliak. Kicserélheted a tűz animációt, a hangokat, és még sorolhatnám. Itt a lényeg az újratöltés. Akik magas pingel játszanak, csúszhat a hang újratöltés közben, illetve a torkolat tűz.

Köszönet:
Külön köszönet FOUTA -nak, a bugok észrevételéért.

Change-Log:
* 1.1
- Javítva: A shotgun nem folytatta az újratöltést.
- Javítva: Ha elfogyott a lőszer a shotgununkba, az animáció nem volt látható az újratöltés.
- Javítva: A Shotgunok elvesztették az újratöltés-állj animációt.
- Törölve: A Shotgun javítások törölve lettek, mert egyébként nem jelentkeznek ezek a hibák.

* 1.0
- Első kiadás

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN_NAME	"Reload Animation Fix"
#define PLUGIN_VERSION	"1.1"
#define PLUGIN_AUTHOR	"Numb"

#define SetPlayerBit(%1,%2)    ( %1 |=  ( 1 << ( %2 & 31 ) ) )
#define ClearPlayerBit(%1,%2)  ( %1 &= ~( 1 << ( %2 & 31 ) ) )
#define CheckPlayerBit(%1,%2)  ( %1 &   ( 1 << ( %2 & 31 ) ) )

#define m_pPlayer 41
#define m_iId 43
#define m_flTimeWeaponIdle 48
#define m_fInReload 54
#define m_fInSpecialReload 55
#define m_fWeaponState 74
#define WEAPONSTATE_USP_SILENCED (1<<0)
#define WEAPONSTATE_M4A1_SILENCED (1<<2)

#define m_pActiveItem 373
#define m_iUserPrefs 510
#define USERPREFS_HAS_SHIELD (1<<24)

new g_iMaxPlayers;
new g_iAlive;

public plugin_init()
{
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
	
	RegisterHam(Ham_Spawn,  "player", "Ham_Spawn_player_Post",  1);
	RegisterHam(Ham_Killed, "player", "Ham_Killed_player_Post", 1);
	
	RegisterHam(Ham_Item_PostFrame, "weapon_glock18",      "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_usp",          "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_deagle",       "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_p228",         "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_elite",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_fiveseven",    "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_mp5navy",      "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_mac10",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_tmp",          "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_p90",          "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_ump45",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_galil",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_famas",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_ak47",         "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_m4a1",         "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_sg552",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_aug",          "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_g3sg1",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_sg550",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_scout",        "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_awp",          "Ham_Item_PostFrame_Pre", 0);
	RegisterHam(Ham_Item_PostFrame, "weapon_m249",         "Ham_Item_PostFrame_Pre", 0);
	
	RegisterHam(Ham_Weapon_WeaponIdle, "weapon_deagle", "Ham_WeaponIdle_deagle_Pre", 0);
	
	RegisterHam(Ham_Item_Deploy, "weapon_m3",     "Ham_Item_Deploy_Pre", 0);
	RegisterHam(Ham_Item_Deploy, "weapon_xm1014", "Ham_Item_Deploy_Pre", 0);
	
	g_iMaxPlayers = clamp(get_maxplayers(), 1, 32);
}

public plugin_unpause()
{
	g_iAlive = 0;
	
	new iPlayers[32], iPlayerNum;
	get_players(iPlayers, iPlayerNum, "a");
	
	for( new iPlayer; iPlayer<iPlayerNum; iPlayer++ )
		SetPlayerBit(g_iAlive, iPlayers[iPlayer]);
}

public client_disconnect(iPlrId)
	ClearPlayerBit(g_iAlive, iPlrId);

public Ham_Spawn_player_Post(iPlrId)
{
	if( is_user_alive(iPlrId) )
		SetPlayerBit(g_iAlive, iPlrId);
	else
		ClearPlayerBit(g_iAlive, iPlrId);
}

public Ham_Killed_player_Post(iPlrId, iAttackerId, iShouldGib)
{
	if( is_user_alive(iPlrId) )
		SetPlayerBit(g_iAlive, iPlrId);
	else
		ClearPlayerBit(g_iAlive, iPlrId);
}

public Ham_Item_PostFrame_Pre(iEnt)
{
	if( !get_pdata_int(iEnt, m_fInReload, 4) )
	{
		static s_iOwner;
		s_iOwner = get_pdata_cbase(iEnt, m_pPlayer, 4);
		
		if( 0<s_iOwner<=g_iMaxPlayers )
		{
			if( CheckPlayerBit(g_iAlive, s_iOwner) )
			{
				if( iEnt==get_pdata_cbase(s_iOwner, m_pActiveItem, 5) )
				{
					switch( get_pdata_int(iEnt, m_iId, 4) )
					{
						case CSW_GLOCK18:
						{
							if( pev(s_iOwner, pev_weaponanim)==((get_pdata_int(s_iOwner, m_iUserPrefs, 5)&USERPREFS_HAS_SHIELD)?4:7) )
								set_pev(s_iOwner, pev_weaponanim, 0);
						}
						case CSW_USP:
						{
							if( get_pdata_int(s_iOwner, m_iUserPrefs, 5)&USERPREFS_HAS_SHIELD )
							{
								if( pev(s_iOwner, pev_weaponanim)==4 )
									set_pev(s_iOwner, pev_weaponanim, 0);
							}
							else if( get_pdata_int(iEnt, m_fWeaponState, 4)&WEAPONSTATE_USP_SILENCED )
							{
								if( pev(s_iOwner, pev_weaponanim)==5 )
									set_pev(s_iOwner, pev_weaponanim, 0);
							}
							else
							{
								if( pev(s_iOwner, pev_weaponanim)==13 )
									set_pev(s_iOwner, pev_weaponanim, 8);
							}
						}
						case CSW_DEAGLE, CSW_FIVESEVEN, CSW_AWP:
						{
							if( pev(s_iOwner, pev_weaponanim)==4 ) //((get_pdata_int(s_iOwner, m_iUserPrefs, 5)&USERPREFS_HAS_SHIELD)?4:4) )
								set_pev(s_iOwner, pev_weaponanim, 0);
						}
						case CSW_P228:
						{
							if( pev(s_iOwner, pev_weaponanim)==((get_pdata_int(s_iOwner, m_iUserPrefs, 5)&USERPREFS_HAS_SHIELD)?4:5) )
								set_pev(s_iOwner, pev_weaponanim, 0);
						}
						case CSW_ELITE:
						{
							if( pev(s_iOwner, pev_weaponanim)==14 )
								set_pev(s_iOwner, pev_weaponanim, 0);
						}
						//case CSW_M3, CSW_XM1014: // there's no need to fix reload issue for this 2 weapons, cause animation #3 is impossible
						//{			   // before start of the reload.
						//	if( 3<=pev(s_iOwner, pev_weaponanim)<=5 ) // 3 for insert, 4 for stop, 5 for start
						//		set_pev(s_iOwner, pev_weaponanim, 0);
						//}
						case CSW_MP5NAVY, CSW_MAC10, CSW_TMP, CSW_P90, CSW_UMP45, CSW_GALIL, CSW_FAMAS, CSW_AK47, CSW_SG552, CSW_AUG:
						{
							if( pev(s_iOwner, pev_weaponanim)==1 )
								set_pev(s_iOwner, pev_weaponanim, 0);
						}
						case CSW_M4A1:
						{
							if( get_pdata_int(iEnt, m_fWeaponState, 4)&WEAPONSTATE_M4A1_SILENCED )
							{
								if( pev(s_iOwner, pev_weaponanim)==4 )
									set_pev(s_iOwner, pev_weaponanim, 0);
							}
							else
							{
								if( pev(s_iOwner, pev_weaponanim)==11 )
									set_pev(s_iOwner, pev_weaponanim, 7);
							}
						}
						case CSW_G3SG1, CSW_SG550, CSW_SCOUT, CSW_M249:
						{
							if( pev(s_iOwner, pev_weaponanim)==3 )
								set_pev(s_iOwner, pev_weaponanim, 0);
						}
					}
				}
			}
		}
	}
}

public Ham_WeaponIdle_deagle_Pre(iEnt)
{
	if( get_pdata_float(iEnt, m_flTimeWeaponIdle, 4)<=0.0 )
	{
		static s_iOwner;
		s_iOwner = get_pdata_cbase(iEnt, m_pPlayer, 4);
		
		if( 0<s_iOwner<=g_iMaxPlayers )
		{
			if( CheckPlayerBit(g_iAlive, s_iOwner) )
			{
				//if( pev(s_iOwner, pev_weaponanim)==5 ) // fix deploy animation glitch for deagle when spectating
				set_pev(s_iOwner, pev_weaponanim, 0);
			}
		}
	}
}

public Ham_Item_Deploy_Pre(iEnt)
	set_pdata_int(iEnt, m_fInSpecialReload, 0, 4);

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	IrOn [ 2014.10.15. 15:07 ]
Hozzászólás témája:	Re: Újratöltési hibák Fixálása
sma 2x van egymásba másolva, töltsd fel jól

Szerző:	Z77 [ 2014.10.15. 18:30 ]
Hozzászólás témája:	Re: Újratöltési hibák Fixálása
Köszönöm, javítva. IrOn123 írta: sma 2x van egymásba másolva, töltsd fel jól

Szerző:	Charlie224 [ 2014.10.17. 20:45 ]
Hozzászólás témája:	Re: Újratöltési hibák Fixálása
kösz , hogy feltöltötted

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/