hlmod.hu :: Migraine 0.5

hlmod.hu https://hlmod.hu/

Migraine 0.5 https://hlmod.hu/viewtopic.php?f=101&t=18767	Oldal: 1 / 1

Szerző:

×X[$]X× Sticky cL. [ 2014.12.31. 16:25 ]

Hozzászólás témája:

Migraine 0.5

Plugin Neve:	Migraine 0.5	Plugint készitette:	ConnorMcLeod
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	ultraibolya

Sziasztok,

A plugint nem én készítettem !.
A plugin lényege hogy adminok bírnak adni játékosoknak olyat hogy fejjel lefele lássanak.
amx_migraine név] [csapat
A plugint tesztelve és működik !

A plugint a mappák szerint:
addons/amxmodx/plugins/migraine.amxx
addons/amxmodx/scripting/migraine.sma
És a végén bele írod az addons/amxmodx/configs/plugins.ini-be az amxx-plugin nevét.

Jó játékot

#include amxmodx
#include amxmisc
#include cstrike
#include fakemeta
#include hamsandwich

#define VERSION "0.0.5"

#define MAX_PLAYERS 32

#define SetUserReversed(%1)		g_bMigraineux |= 1<<(%1 & 31)
#define ClearUserReversed(%1)		g_bMigraineux &= ~( 1<<(%1 & 31) )
#define HasUserMigraine(%1)		g_bMigraineux &  1<<(%1 & 31)

enum _:GlobalState {None, Terrorists, Cts, All}

new g_bMigraineux

new Float:g_vecPunchAngles[MAX_PLAYERS+1][3]
new g_iFfPlayerPreThink
new g_iGlobalState

public plugin_init()
{
	register_plugin("Migraine", VERSION, "ConnorMcLeod")

RegisterHam(Ham_Spawn, "player", "Player_Spawn_Post", 1)

register_concmd("amx_migraine", "AdminCommand_Migraine", ADMIN_LEVEL_A, "- < name/@CT/@TE/@ALL > < 0/1 >")
}

public client_putinserver( id )
{
	ClearUserReversed(id)
	CheckForward()
}

public client_disconnect( id )
{
	ClearUserReversed(id)
	CheckForward()
}

public Player_Spawn_Post( id )
{
	if( is_user_alive(id) )
	{
		switch( g_iGlobalState )
		{
			case Terrorists, Cts:
			{
				if( g_iGlobalState == _:cs_get_user_team(id) )
				{
					SetUserReversed(id)
				}
				else
				{
					ClearUserReversed(id)
					CheckForward()
				}
			}
			case All:
			{
				SetUserReversed(id)
				CheckForward()
			}
		}
	}
}

public AdminCommand_Migraine(id, level, cid)
{
	if( cmd_access(id, level, cid, 3) )
	{
		new szTarget[32], szOnOff[2], iPlayer, iOnOff
		read_argv(1, szTarget, charsmax(szTarget))
		read_argv(2, szOnOff, charsmax(szOnOff))

switch( szOnOff[0] )
		{
			case '0':
			{
				iOnOff = 0
			}
			case '1':
			{
				iOnOff = 1
			}
			default:
			{
				return PLUGIN_HANDLED
			}
		}

if( szTarget[0] == '@' )
		{
			if( !iOnOff )
			{
				g_bMigraineux = 0
				g_iGlobalState = None
				CheckForward()
				for(new i; i<sizeof(g_vecPunchAngles); i++)
				{
					g_vecPunchAngles[iPlayer][0] = 0.0
					g_vecPunchAngles[iPlayer][1] = 0.0
				}
				return PLUGIN_HANDLED
			}

new iPlayers[MAX_PLAYERS], iNum
			get_players(iPlayers, iNum)
			for(new i; i<iNum; i++)
			{
				iPlayer = iPlayers[i]
				switch( szTarget[1] )
				{
					case 'a','A':
					{
						g_iGlobalState = All
						SetUserReversed(iPlayer)		
					}
					case 't', 'T':
					{
						g_iGlobalState = Terrorists

if( cs_get_user_team(iPlayer) == CS_TEAM_T )
						{
							SetUserReversed(iPlayer)
						}
						else
						{
							ClearUserReversed(iPlayer)
						}
					}
					case 'c', 'C':
					{
						g_iGlobalState = Cts

if( cs_get_user_team(iPlayer) == CS_TEAM_CT )
						{
							SetUserReversed(iPlayer)
						}
						else
						{
							ClearUserReversed(iPlayer)
						}
					}
					default:
					{
						return PLUGIN_HANDLED
					}
				}
				g_vecPunchAngles[iPlayer][0] = 0.0
				g_vecPunchAngles[iPlayer][1] = 0.0
			}
		}
		else
		{
			iPlayer = cmd_target(id, szTarget, CMDTARGET_OBEY_IMMUNITY|CMDTARGET_ALLOW_SELF)
			if( iPlayer )
			{
				if( iOnOff )
				{
					SetUserReversed(iPlayer)
				}
				else
				{
					ClearUserReversed(iPlayer)
				}
				g_vecPunchAngles[iPlayer][0] = 0.0
				g_vecPunchAngles[iPlayer][1] = 0.0
			}
		}
		CheckForward()
	}
	return PLUGIN_HANDLED
}

public PlayerPreThink( id )
{
	if(HasUserMigraine(id) && is_user_alive(id))
	{
		if( g_vecPunchAngles[id][1] < 180.0 )
		{
			g_vecPunchAngles[id][1] += 2.0
			g_vecPunchAngles[id][0] = g_vecPunchAngles[id][1] * 2.0
		}
		else
		{
			g_vecPunchAngles[id][0] = 0.0
		}

static Float:vecPunchAngle[3]
		vecPunchAngle[0] = g_vecPunchAngles[id][0]
		vecPunchAngle[1] = g_vecPunchAngles[id][0]
		vecPunchAngle[2] = g_vecPunchAngles[id][1]

set_pev(id, pev_punchangle, vecPunchAngle)
	}
}

CheckForward()
{
	if( !g_bMigraineux != !g_iFfPlayerPreThink )
	{
		if( g_bMigraineux )
		{
			g_iFfPlayerPreThink = register_forward(FM_PlayerPreThink, "PlayerPreThink")
		}
		else
		{
			unregister_forward(FM_PlayerPreThink, g_iFfPlayerPreThink)
			g_iFfPlayerPreThink = 0
		}
	}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	NuD[!]e [ 2015.01.01. 16:50 ]
Hozzászólás témája:	Re: Migraine 0.5
Szerintem jó teszteltem. , de nincs sok értelme, fun szerverekbe jó!:D

Szerző:	×X[$]X× Sticky cL. [ 2015.01.01. 18:33 ]
Hozzászólás témája:	Re: Migraine 0.5
Jah, Ezzel a pluginnal szórakozni lehet meg hülyéskedni

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/