hlmod.hu :: Anti-No Flash Hack

hlmod.hu https://hlmod.hu/

Anti-No Flash Hack https://hlmod.hu/viewtopic.php?f=101&t=18787	Oldal: 1 / 1

Szerző:

M4kk3R [ 2015.01.01. 21:10 ]

Hozzászólás témája:

Anti-No Flash Hack

Plugin Neve:	Anti-No Flash Hack	Plugint készitette:	sHiFT
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	Badboy.killer

Sziasztok! Ma 1 olyan plugint hoztam el nektek ami blockolja a Flash hacket!

Keszitette: sHiFT
en csak feltoltottem!

Teszt: VOLT

Cvar:

//Be legyen kapcsolva a plugin.(Alap: 1)
anti_noflash_on

//Eltavolitja a jatekos vakulasat teszteles celjabol (utanozza a no flash cheat et mindenki szamara). (Alap (ajanlom): 0)
anti_noflash_demo

//keslelteti azt amikor megszunik a vaksag. (alap: 0.0). javasolom: maradjon a 0.0.
anti_noflash_delay

//figyelmen kivul hagyja a kivalasztott csapatot: 0 = Mind1, 1 = Terrorista, 2 = CT (Alap: 0)
anti_noflash_ignore

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>
#include <cstrike>

#define PLUGIN "Anti-No Flash"
#define VERSION "1.0.7"
#define AUTHOR "sHiFT"

new Float:g_flashed_until[33];

new pcv_on;
new pcv_demo;
new pcv_delay;
new pcv_ignore;
new g_msg_screen_fade;
new g_isBot[33];
new g_isAlive[33];
new g_team[33];
new g_plugin_on, g_ignore;

public plugin_init() {

register_plugin(PLUGIN, VERSION, AUTHOR);
	register_cvar("anti_noflash_version", VERSION, FCVAR_SERVER);	
	
	pcv_on = register_cvar ("anti_noflash_on", "1");
	pcv_demo = register_cvar ("anti_noflash_demo", "0");
	pcv_delay = register_cvar ("anti_noflash_delay", "0.0");
	pcv_ignore = register_cvar ("anti_noflash_ignore_team", "0");

register_event("ScreenFade", "event_flashed", "b", "7=255");
	register_forward(FM_AddToFullPack, "fw_addtofullpack", 0);
	
	g_msg_screen_fade = get_user_msgid("ScreenFade");
	
	//Just for caching purposes
	RegisterHam( Ham_Spawn, "player", "fw_PlayerSpawn", 1);
	RegisterHam( Ham_Killed, "player", "fw_PlayerKilled", 1);

}

public event_flashed(id){
	
	//Cache this value so it is not called in AddToFullPack
	g_plugin_on = get_pcvar_num(pcv_on);
	
	if (!g_plugin_on || !is_user_connected(id) )
		return PLUGIN_CONTINUE;

g_ignore = get_pcvar_num(pcv_ignore);
	
	//Up to when this player should be flashed
	g_flashed_until[id] = read_data(2)/4096.0 + get_gametime() + get_pcvar_float(pcv_delay);

if(get_pcvar_num(pcv_demo)){	
		client_print(id, print_chat, "Gametime: %0.2f - Flashed until: %0.2f",get_gametime(),g_flashed_until[id]);
		remove_flash(id);
	}
	
	return PLUGIN_CONTINUE;

}

public fw_addtofullpack(es, e, ent, host, flags, player, set){
	
	//
	if (!g_plugin_on || !g_isAlive[host] || g_isBot[host])
		return FMRES_IGNORED;
	
	//
	if(g_ignore==g_team[host])
		return FMRES_IGNORED;
	
	if(player)
	{
		//
		if(!g_isAlive[ent] || ent == host)
			return FMRES_IGNORED;
	} else 
		if(pev_valid(ent))
		{
			//
			static Classname[33];
			pev(ent, pev_classname, Classname,32);
			new is_grenade = equal(Classname,"grenade");
	
			// 
			//
			if(!is_grenade || pev(ent, pev_owner)==host)		
				return FMRES_IGNORED;
	
		} else
			return FMRES_IGNORED;
	
	//
	if(get_gametime() < g_flashed_until[host])
	{
		//client_print(host, print_chat, "Gametime: %0.2f - Flashed until: %0.2f",get_gametime(),g_flashed_until[host]);
		forward_return(FMV_CELL, 0);
		return FMRES_SUPERCEDE;
	}
	
	return FMRES_IGNORED;

}

public remove_flash(id){
		
	//
	message_begin(MSG_ONE_UNRELIABLE, g_msg_screen_fade, {0, 0, 0}, id);
	write_short(0);
	write_short(0);
	write_short(0);
	write_byte(0);
	write_byte(0);
	write_byte(0);
	write_byte(0);
	message_end();

}

//Caching functions
public client_putinserver(id)
{
        g_isBot[id] = is_user_bot(id);
}

public client_disconnect(id)
{
    g_isAlive[id] = false;
    g_isBot[id] = false;
}

public fw_PlayerSpawn(id)
{
	g_isAlive[id] = is_user_alive(id);
	g_team[id] = cs_get_user_team(id);
	//g_team[id] = get_user_team(id);
}

public fw_PlayerKilled(id)
{
    g_isAlive[id] = false;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	Zeei [ 2015.01.01. 21:31 ]
Hozzászólás témája:	Re: Anti-No Flash Hack
cvarok hianyoznak!

Szerző:	PiStA99 [ 2015.01.01. 22:17 ]
Hozzászólás témája:	Re: Anti-No Flash Hack
Cvarok ?

Szerző:	Zeei [ 2015.01.01. 22:22 ]
Hozzászólás témája:	Re: Anti-No Flash Hack
PiStA99 írta: Cvarok ? Talan te a playback-em vagy?:D vannak hozza...

Szerző:	M4kk3R [ 2015.01.03. 11:14 ]
Hozzászólás témája:	Re: Anti-No Flash Hack
Zeei írta: cvarok hianyoznak! Javitva!

Szerző:	apple [ 2015.04.20. 09:24 ]
Hozzászólás témája:	Re: Anti-No Flash Hack
Hibás a plugin nem működik! És ez 100%

Szerző:	6almasok [ 2015.04.20. 16:49 ]
Hozzászólás témája:	Re: Anti-No Flash Hack
apple írta: Hibás a plugin nem működik! És ez 100% Pedig apple működik az én szerveremen is fent van és 100%-osan megy!

Szerző:	Kaszkador [ 2020.06.21. 14:26 ]
Hozzászólás témája:	Re: Anti-No Flash Hack
Nekem működik.Csak aynni ahiba hogy eltűnik az ember flash-kor. Az miért van?

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/