hlmod.hu :: Zeus x27 Taser 1.0.0

hlmod.hu https://hlmod.hu/

Zeus x27 Taser 1.0.0 https://hlmod.hu/viewtopic.php?f=101&t=21879	Oldal: 1 / 1

Szerző:

Akosch:. [ 2015.08.07. 13:57 ]

Hozzászólás témája:

Zeus x27 Taser 1.0.0

Plugin Neve:	Zeus x27 Taser 1.0.0	Plugint készitette:	Akosch:.
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	ultraibolya

[kozep]Zeus x27 Taser[/kozep]
[kozep]v1.0.0 by Akosch:.[/kozep]

Mit tud a plugin?
Hozzáad egy új fegyvert(sokkolót) a játékhoz, amit $-ért tudunk megvenni, ha chatbe beírjuk, hogy "/zeus".
Ez a kis sokkoló 1-et tud lőni, de az megfelelő távolságból ( mert minél messzebb vagy annál kevesebbet sebez ) halálos, megvétel után ez érhető el a kés helyett. Lövéskor, ha eltalálsz valakit azt egy kettőtök közti villám effekt jelzi ( cvarokkal állítható szín, szélesség ), ha nem találod el vele az ellenfeledet, akkor csak simán elveszted a fegyvert.
CS:GO -s változatához hasonló model, és hangok + a konzolban kiírt halál üzenet is jelzi, hogy te egy "zeus x27 taser" -el ölted meg a játékost nem késsel.

Cvarok:

Zeus_Prise( 0 - felfelé ) - Mennyibe kerüljön a zeus.($)
Zeus_Distance( 0.0 - felfelé ) - Maximum hány méterről hasson.(float értékben kell megadni!)
Zeus_Beam_Width( 0 - 255 ) - Milyen széles legyen a villám effekt.
Zeus_Beam_Red( 0 - 255 ) - Piros értékét adja meg RGBA színskálán a villámhoz.
Zeus_Beam_Green( 0 - 255 ) - Zöld értékét adja meg RGBA színskálán a villámhoz.
Zeus_Beam_Blue( 0 - 255 ) - Kék értékét adja meg RGBA színskálán a villámhoz.
Zeus_Beam_Alpha( 0 - 255 ) - Alpha értékét adja meg RGBA színskálán a villámhoz.

Képek(nagyobb méretért katt a képre):

Konzol üzenet:

Villám effekt(fehérben, ~100-as szélességgel):

Információ!
Nagy távolságból fix 1-et sebez!
Csak az alap vásárlási zónában tudod megvenni!
Telepítés a zip -ben található mappák szerint!

Welcome to the AMX Mod X 1.8.1-300 Compiler.
Copyright (c) 1997-2013 ITB CompuPhase, AMX Mod X Team

Header size: 1560 bytes
Code size: 10140 bytes
Data size: 6128 bytes
Stack/heap size: 16384 bytes; max. usage is unknown, due to recursion
Total requirements: 34212 bytes
Done.

Köszönet
a skinért és a hangokért: http://cs.gamebanana.com/skins/135855
a sprite -ért: http://www.hlmod.hu/viewtopic.php?f=101&t=14767
a teszt lehetőségért: [profil]DecToR[/profil]-nak.

A plugin tesztelve volt, mi nem találtunk hibát, bugokat.

#include <amxmodx>
#include <amxmisc>
enum Color
{
	NORMAL = 1, // clients scr_concolor cvar color
	GREEN, // Green Color
	TEAM_COLOR, // Red, grey, blue
	GREY, // grey
	RED, // Red
	BLUE, // Blue
}

new TeamName[][] = 
{
	"",
	"TERRORIST",
	"CT",
	"SPECTATOR"
}

ColorChat(id, Color:type, const msg[], {Float,Sql,Result,_}:...)
{
	static message[256];

switch(type)
	{
		case NORMAL: // clients scr_concolor cvar color
		{
			message[0] = 0x01;
		}
		case GREEN: // Green
		{
			message[0] = 0x04;
		}
		default: // White, Red, Blue
		{
			message[0] = 0x03;
		}
	}

vformat(message[1], 251, msg, 4);
	message[192] = '^0';

static team, ColorChange, index, MSG_Type;
	
	if(id)
	{
		MSG_Type = MSG_ONE;
		index = id;
	} else {
		index = FindPlayer();
		MSG_Type = MSG_ALL;
	}
	
	team = get_user_team(index);
	ColorChange = ColorSelection(index, MSG_Type, type);

ShowColorMessage(index, MSG_Type, message);
		
	if(ColorChange)
	{
		Team_Info(index, MSG_Type, TeamName[team]);
	}
}

ShowColorMessage(id, type, message[])
{
	message_begin(type, get_user_msgid("SayText"), _, id);
	write_byte(id)		
	write_string(message);
	message_end();	
}

Team_Info(id, type, team[])
{
	message_begin(type, get_user_msgid("TeamInfo"), _, id);
	write_byte(id);
	write_string(team);
	message_end();

return 1;
}

ColorSelection(index, type, Color:Type)
{
	switch(Type)
	{
		case RED:
		{
			return Team_Info(index, type, TeamName[1]);
		}
		case BLUE:
		{
			return Team_Info(index, type, TeamName[2]);
		}
		case GREY:
		{
			return Team_Info(index, type, TeamName[0]);
		}
	}

return 0;
}

FindPlayer()
{
	static i;
	i = -1;

while(i <= get_maxplayers())
	{
		if(is_user_connected(++i))
		{
			return i;
		}
	}

return -1;
}

#include <cstrike>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

#pragma semicolon 1

#define PLUGIN "Zeus X27 Taser"
#define VERSION "1.0.0"
#define AUTHOR "Akosch:."

#define is_user_valid(%0)		(1 <= %0 <= 32)
#define get_user_has_weapon(%0,%1)	(get_user_weapon(%0) == %1)
#define SLOT 32

new bool:g_bZeus[SLOT + 1], bool:g_bAttacking[SLOT + 1], g_pCvar[7], g_pSpriteModel;

stock const g_sServerPrefix[] = {"[Információ]"};
stock const g_sWeaponModel[] = {"models/v_zeus.mdl"};

stock const g_sDefaultSounds[][] =
{
	{"weapons/knife_deploy1.wav"},
	{"weapons/knife_hit1.wav"},
	{"weapons/knife_hit2.wav"},
	{"weapons/knife_hit3.wav"},
	{"weapons/knife_hit4.wav"},
	{"weapons/knife_hitwall1.wav"},
	{"weapons/knife_slash1.wav"},
	{"weapons/knife_slash2.wav"},
	{"weapons/knife_stab.wav"}
};

stock const g_sZeusSounds[][] =
{
	{"weapons/zeus_deploy1.wav"},
	{"weapons/zeus_hit1.wav"},
	{"weapons/zeus_hit2.wav"},
	{"weapons/zeus_hit3.wav"},
	{"weapons/zeus_hit4.wav"},
	{"weapons/zeus_hitwall1.wav"},
	{"weapons/zeus_slash1.wav"},
	{"weapons/zeus_slash2.wav"},
	{"weapons/zeus_stab.wav"}
};

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);

register_forward(FM_EmitSound, "fwdEmitSound", 0);
	register_forward(FM_TraceLine, "fwdTraceLine", 0);
	register_forward(FM_TraceHull, "fwdTraceHull", 1);

RegisterHam(Ham_Killed, "player", "fwdDeathPost", 1);
	RegisterHam(Ham_TakeDamage, "player", "fwdDamagePre", 0);
	RegisterHam(Ham_TakeDamage, "player", "fwdDamagePost", 1);
	RegisterHam(Ham_Item_Deploy, "weapon_knife", "fwdWeaponSwitchPost", 1);
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_knife", "fwdWpnPrimAttackPost", 1);
	RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_knife", "fwdWpnSecAttackPost", 1);

register_clcmd("say /zeus", "fnBuyZeus", ADMIN_ALL);
	
	register_message(get_user_msgid("DeathMsg"), "msgDeath");

g_pCvar[0] = register_cvar("Zeus_Prise", "750");
	g_pCvar[1] = register_cvar("Zeus_Distance", "3.0");
	g_pCvar[2] = register_cvar("Zeus_Beam_Width", "100");
	g_pCvar[3] = register_cvar("Zeus_Beam_Red", "120");
	g_pCvar[4] = register_cvar("Zeus_Beam_Green", "240");
	g_pCvar[5] = register_cvar("Zeus_Beam_Blue", "180");
	g_pCvar[6] = register_cvar("Zeus_Beam_Alpha", "100");
}

public plugin_precache()
{
	precache_model(g_sWeaponModel);
	
	g_pSpriteModel = precache_model("sprites/lightning.spr");
	
	for(new i; i < sizeof(g_sZeusSounds); i++)
		precache_sound(g_sZeusSounds[i]);
}

public client_connect(id)
	g_bZeus[id] = false;

public client_disconnect(id)
	g_bZeus[id] = false;

public fwdDeathPost(iVictim, iKiller)
	g_bZeus[iVictim] = false;

public fnBuyZeus(id)
{
	new iPrise = get_pcvar_num(g_pCvar[0]);
	
	if(!is_user_alive(id))
	{
		ColorChat(id, GREEN, "%s ^1Csak élők tudnak ^3Zeus x27 Taser ^1-t venni^4!", g_sServerPrefix);
		return;
	}
	else if(!cs_get_user_buyzone(id))
	{
		ColorChat(id, GREEN, "%s ^1Csak a vásárló zónában tudsz vásárolni^4!", g_sServerPrefix);
		return;
	}
	else if(g_bZeus[id])
	{
		ColorChat(id, GREEN, "%s ^1Neked már van egy ^3Zeus x27 Taser ^1-d^4!", g_sServerPrefix);
		return;
	}
	else if(cs_get_user_money(id) < iPrise)
	{
		ColorChat(id, GREEN, "%s ^1Nincs elég pénzed megvenni^4!", g_sServerPrefix);
		return;
	}
	else
	{
		g_bZeus[id] = true;
		cs_set_user_money(id, cs_get_user_money(id) - iPrise);
		ColorChat(id, GREEN, "%s ^1Sikeresen vettél egy ^3Zeus x27 Taser ^1-t^4!", g_sServerPrefix);
	}
}

public fwdWeaponSwitchPost(iWeapon)
{
	new id = pev(iWeapon, pev_owner);

if(!is_user_valid(id) || !is_user_alive(id))
		return HAM_SUPERCEDE;

if(g_bZeus[id])
	{
		set_pev(id, pev_viewmodel2, g_sWeaponModel);
		
		return HAM_SUPERCEDE;
	}
	
	return HAM_IGNORED;
}

public fwdDamagePre(iVictim, iInflictor, iAttacker, Float:fDamage)
	if(get_user_has_weapon(iAttacker, CSW_KNIFE) && g_bZeus[iAttacker])
	{
		new Float:fVicOrigin[3], Float:fAttOrigin[3], Float:fNewDmg;

g_bAttacking[iVictim] = true;

pev(iVictim, pev_origin, fVicOrigin);
		pev(iAttacker, pev_origin, fAttOrigin);

(200.0 - get_distance_f(fVicOrigin, fAttOrigin)) > 0.0 ? (fNewDmg = 200.0 - get_distance_f(fVicOrigin, fAttOrigin)) : (fNewDmg = 1.0);

SetHamParamFloat(4, fNewDmg);

new iWidth, iRed, iGreen, iBlue, iAlpha;

iWidth = get_pcvar_num(g_pCvar[2]);
		iRed = get_pcvar_num(g_pCvar[3]);
		iGreen = get_pcvar_num(g_pCvar[4]);
		iBlue = get_pcvar_num(g_pCvar[5]);
		iAlpha = get_pcvar_num(g_pCvar[6]);

Create_Te_Beaments(iAttacker, iVictim, g_pSpriteModel, 0, 10, 4, iWidth, 5, iRed, iGreen, iBlue, iAlpha, 15);
	}

public fwdDamagePost(iVictim, iInflictor, iAttacker, Float:fDamage)
	if(is_user_alive(iVictim))
		g_bAttacking[iVictim] = false;

public fwdEmitSound(id, iChannel, const sSound[])
{
	if(!is_user_valid(id) || !is_user_alive(id) || (iChannel != 1 && iChannel != 3))
		return FMRES_IGNORED;

if(!g_bZeus[id])
		return FMRES_IGNORED;

static i;
	for(i = 0; i <= sizeof(g_sDefaultSounds); i++)
	{
		if(equali(g_sDefaultSounds[i], sSound))
		{
			engfunc(EngFunc_EmitSound, id, CHAN_WEAPON, g_sZeusSounds[i], 1.0, ATTN_NORM, 0, PITCH_NORM);
			
			return FMRES_SUPERCEDE;
		}
	}
	
	return FMRES_IGNORED;
}

public fwdWpnPrimAttackPost(iWeapon)
	fnWeapon_Attack(iWeapon);

public fwdWpnSecAttackPost(iWeapon)
	fnWeapon_Attack(iWeapon);

fnWeapon_Attack(iWeapon)
{
	if(!pev_valid(iWeapon))
		return;
	
	static id;
	id = pev(iWeapon, pev_owner);
	
	if(!is_user_valid(id))
		return;
	
	if(get_user_has_weapon(id, CSW_KNIFE) && g_bZeus[id])
		g_bZeus[id] = false;
}

public fwdTraceLine(Float:fStart[3], Float:fEnd[3], conditions, id, ptr)
	return fnTrace(id, ptr,fStart,fEnd,conditions);

public fwdTraceHull(Float:fStart[3], Float:fEnd[3], conditions, hull, id, ptr)
	return fnTrace(id, ptr,fStart,fEnd,conditions,true,hull);

fnTrace(id, ptr, Float:fStart[3], Float:fEnd[3],iNoMonsters, bool:hull = false, iHull = 0)
{
	if(is_user_alive(id) && get_user_has_weapon(id, CSW_KNIFE) && g_bZeus[id])
	{		
		xs_vec_sub(fEnd,fStart,fEnd);
		xs_vec_mul_scalar(fEnd,get_pcvar_float(g_pCvar[1]),fEnd);
		xs_vec_add(fEnd,fStart,fEnd);

hull ? engfunc(EngFunc_TraceHull,fStart,fEnd,iNoMonsters,iHull,id,ptr) : engfunc(EngFunc_TraceLine,fStart,fEnd,iNoMonsters, id,ptr);
	}
	
	return FMRES_IGNORED;
}

public msgDeath(iMsgId, sMsgDest, id)
{
	new sWeapon[32], iVictim;

get_msg_arg_string(4, sWeapon, charsmax(sWeapon));

iVictim = get_msg_arg_int(2);

if(equal(sWeapon, "knife")  && g_bAttacking[iVictim])
		set_msg_arg_string(4, "zeus x27 taser");

return PLUGIN_CONTINUE;
}

stock Create_Te_Beaments(iStartEnt, iEndEnt, iSprite, iStartFrame, iFrameRate, iLife, iWidth, iNoise, iRed, iGreen, iBlue, iAlpha, iSpeed)
{
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_BEAMENTS);
	write_short(iStartEnt);
	write_short(iEndEnt);
	write_short(iSprite);
	write_byte(iStartFrame);
	write_byte(iFrameRate);
	write_byte(iLife);
	write_byte(iWidth);
	write_byte(iNoise);
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iAlpha);
	write_byte(iSpeed);
	message_end();
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	Messi10 [ 2015.08.16. 10:20 ]
Hozzászólás témája:	Re: Zeus x27 Taser 1.0.0
Nekem be jön

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/