hlmod.hu :: Glowing Color

hlmod.hu https://hlmod.hu/

Glowing Color https://hlmod.hu/viewtopic.php?f=101&t=23358	Oldal: 1 / 1

Szerző:

kengurumancs [ 2015.12.31. 13:31 ]

Hozzászólás témája:

Glowing Color

Plugin Neve:	Glowing Color	Plugint készitette:	Garey
Játék:	Mind	Kategória:	Admin parancsok
Eredeti link:	Megnézem	Jóváhagyó:	kiki

Glowing Color
By Speed

Leírás:
Ez a plugin lehetővé teszi hogy a játékos sebességétől függve, izzani/ világítani fog az ember.
Fun szerverekre ajánlom.

Cvarok:
gbs_start [1-0] - Játékos világítása mapkezdésnél?
gbs_amount [0-255] - Izzás színe.
gbs_glow_min_speed - Mennyi sebességtől kezdjen színezni a plugin.
gbs_glow_max_speed - Mennyi sebességig színezzen a plugin.

Telepítés:
Amxx fájl a plugins mappába, majd a plugin nevét a plugins.ini -be írd be!
Sma-t scripting mappába. (nem szükséges)

#include <amxmodx>
#include <fakemeta>
#include <fun>

#define PLUGIN "Glowing Color By Speed"
#define VERSION "1.0"
#define AUTHOR "Garey"

// Ha nem akarod akkor ird ele. /chaten irja a izzast.
#define ECHOCMD

#define FREQ 0.1

new bool:plrGlow[33] = { true, ... };

new TaskEnt,g_showglow,g_glowamount,g_minspeed,g_maxspeed, maxplayers

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_cvar("Garey", "Glowing Color By Speed", FCVAR_SERVER)
	register_forward(FM_Think, "Think")
	
	TaskEnt = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"))	
	set_pev(TaskEnt, pev_classname, "speedometer_think")
	set_pev(TaskEnt, pev_nextthink, get_gametime() + 1.01)
	
	register_clcmd("say /glow", "toogleGlow")
	
	g_showglow = register_cvar("gbs_start", "0")
	g_glowamount=register_cvar("gbs_amount", "25")
	g_minspeed=register_cvar("gbs_glow_min_speed", "250")
	g_maxspeed=register_cvar("gbs_glow_max_speed", "300")
	
	maxplayers = get_maxplayers()
}

public Think(ent)
{
	if(ent == TaskEnt) 
	{
		SpeedTask()
		set_pev(ent, pev_nextthink,  get_gametime() + FREQ)
	}
}

public client_putinserver(id)
{
	plrGlow[id] = (get_pcvar_num(g_showglow)) > 0 ? true : false
}

public toogleGlow(id)
{
	if( plrGlow[id] )
	{
		client_print(id, print_chat, "[HLMOD] Izzas nincs engedelyezve.");
		set_user_rendering(id,kRenderFxGlowShell,0,0,0,kRenderNormal,0)
		plrGlow[id] = false;
	}
	else
	{
		client_print(id, print_chat, "[HLMOD] Izzas engedelyezve.");
		plrGlow[id] = true;
	}
	
	#if defined ECHOCMD
	return PLUGIN_CONTINUE;
	#else
	return PLUGIN_HANDLED;
	#endif
}

stock dynamicColor(min,max,Float:value,&red,&green,&blue)
{ //Don`t launch with max ~= min 
	#define MaxC 255
	#define MinC 0
	#define DtC 255
	
	if (value>=max)
	{
		red=MaxC;
		green=MinC;
		blue=MinC;
		return;
	}
	else if (value<=min)
	{
		red=MinC;
		green=MinC;
		blue=MaxC;
		return;
	}
	
	new Float:step = (max-min)/4.0;
	new Float:dt = value-min;
	
	if (dt <= step)
	{
		red   = MinC;
		green = floatround(dt*(DtC/step));
		blue  = MaxC;
	}
	else if (dt-=step, dt <= step)
	{
		red   = MinC;
		green = MaxC;
		blue  = floatround((step-dt)*(DtC/step));
	}
	else if (dt-=step, dt <= step)
	{
		red   = floatround(dt*(DtC/step));
		green = MaxC;
		blue  = MinC;
	}
	else
	{
		dt-=step;
		red   = MaxC;
		green = floatround((step-dt)*(DtC/step));
		blue  = MinC;
	}
	return;
}

SpeedTask()
{
static i, target
static Float:velocity[3]
static Float:speedh

for(i=1; i<=maxplayers; i++)
{
	if(!is_user_connected(i)) continue
	if(!plrGlow[i]) continue
	
	target = pev(i, pev_iuser1) == 4 ? pev(i, pev_iuser2) : i
	pev(target, pev_velocity, velocity)
	
	speedh = floatsqroot(floatpower(velocity[0], 2.0) + floatpower(velocity[1], 2.0))
	
	static r, g, b
	dynamicColor(get_pcvar_num(g_minspeed),get_pcvar_num(g_maxspeed),speedh,r,g,b)
	set_user_rendering(i,kRenderFxGlowShell,r,g,b,kRenderNormal,get_pcvar_num(g_glowamount))	
}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:

joxxa4cfg [ 2015.12.31. 22:02 ]

Hozzászólás témája:

Re: Glowing Color

Akit érdekel így néz ki, természetesen a színt sebességtől függően változtatja.

Csatolmányok:

10_screenshots_2015-12-31_00007.jpg [ 242.2 KiB | Megtekintve 2443 alkalommal ]

Szerző:	FonoK [ 2016.03.14. 18:16 ]
Hozzászólás témája:	Re: Glowing Color
Sziasztok! Elsősorban köszönöm a feltöltést. Én 0-ra állítotam be a minimum értéket, szóval akkor "alapból" kéne izzania ugye? Mert saját magamon nem látom hogy színes lenne a testem.. Vagy csak mások láthatják rajtam? Előre is köszönöm a választ (Új, dust2 szerveremen próbáltam ki, egyenlőre még nem publikus, szóval csak "magamon" próbáltam)

Szerző:	kengurumancs [ 2016.03.14. 18:33 ]
Hozzászólás témája:	Re: Glowing Color
Szia! Ha, jól tudom alap sebességnél nem izzék az ember. Illetve, ha mindent leveszel nullára sehogy se izzik.

Szerző:	FonoK [ 2016.03.14. 18:37 ]
Hozzászólás témája:	Re: Glowing Color
kengurumancs írta: Szia! Ha, jól tudom alap sebességnél nem izzék az ember. Illetve, ha mindent leveszel nullára sehogy se izzik. Ó, értem akkor ezért nem működött. Aakkor át is állítom gyors köszönöm szépen

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/