hlmod.hu :: Simple Swear Filter

hlmod.hu https://hlmod.hu/

Simple Swear Filter https://hlmod.hu/viewtopic.php?f=101&t=24718	Oldal: 1 / 2

Szerző:

mforce [ 2016.04.26. 13:01 ]

Hozzászólás témája:

Simple Swear Filter

Plugin Neve:	Simple Swear Filter	Plugint készitette:	mforce
Játék:	Mind	Kategória:	Általános célú
Eredeti link:	Megnézem	Jóváhagyó:	LyleChriss

Simple Swear Filter
v1.0 by mforce

Leírás:
Egy fájlban megadhatók a chaten látni nem kívánt káromkodások.
Kicsillagozásra kerülnek a szavak hosszúságuknak megfelelően vagy teljes elrejtésre az egész üzenet beállítás szerint (néhány chat pluginon csak ez a módszer működik).

Konfiguráció:
Megadhatjuk, hogy ne kicsillagozza, hanem elrejtse a káromkodó üzeneteket a plugin, ehhez a

Kód:

//#define JUST_HIDE

szövegből el kell távolítani a # elől a két // jelet.

Adjuk meg a "configs/simple_swear_filter.ini" fájlban a nem kívánt káromkodásokat
külön külön sorba idézőjelekkel.
Példa :lol:

Kód:

"buzi"
"geci"
"fasz"
"bazdmeg"
"anyád"

#include <amxmodx>

/*	Remove the // before #define to hide the messages with swear words.
	Default: swears replaced to stars.
	Example: fuck - **** 												*/

//#define JUST_HIDE

new const PLUGIN[] = "Simple Swear Filter";
new const VERSION[] = "1.0";
new const AUTHOR[] = "mforce";

new Array:swearlist;
new g_ArraySize;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_clcmd("say", "sayhandler");
	register_clcmd("say_team", "sayhandler");
	swearlist = ArrayCreate(32);
}

public plugin_cfg() {
	new sBuffer[256], sFile[64], sData[1][32], pFile;
	get_localinfo("amxx_configsdir", sFile, charsmax(sFile));
	format(sFile, charsmax(sFile), "%s/simple_swear_filter.ini", sFile);
 
	pFile = fopen(sFile, "rt");
	if(pFile) {		
		while(!feof(pFile)) {
			fgets(pFile, sBuffer, charsmax(sBuffer));
			trim(sBuffer);
			if(sBuffer[0] == ';' || sBuffer[0] == EOS) continue;
 
			parse(sBuffer, sData[0], charsmax(sData[]));
			ArrayPushString(swearlist, sData[0]);
		}
		fclose(pFile);
		g_ArraySize = ArraySize(swearlist);
	}
	else write_file(sFile, ";^"kurva^"");
}

public sayhandler(id) {
	new szMessage[190]; read_args(szMessage, charsmax(szMessage));
	remove_quotes(szMessage);
	
	new szCheck[32], bool:bFound;

for(new i; i<g_ArraySize; i++) {
		ArrayGetString(swearlist, i, szCheck, charsmax(szCheck));
		if(containi(szMessage, szCheck) != -1) {
			bFound = true;
			
			#if !defined JUST_HIDE
			new szSaid[32], iChars = strlen(szCheck);
			
			for(new a; a<iChars; a++)
				szSaid[a] = '*';
			
			replace_all(szMessage, charsmax(szMessage), szCheck, szSaid);
			#else
			break;
			#endif
		}
	}
	
	if(bFound) {
		#if !defined JUST_HIDE
		new cmd[32]; read_argv(0, cmd, charsmax(cmd));
		engclient_cmd(id, cmd, szMessage);
		#endif

return PLUGIN_HANDLED;
	}
	
	return PLUGIN_CONTINUE;
}

public plugin_end() {
	ArrayDestroy(swearlist);
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	LyleChriss [ 2016.04.26. 14:19 ]
Hozzászólás témája:	Re: Simple Swear Filter
Nem tudom jóváfele hagyni, mert valamiért a pluginnál ki van jelentkezve HLmodról, minden más oldalnál meg rendesen műköszik a dolog. Szerk: a HSZ után egyből jó lett.

Szerző:	mforce [ 2016.04.26. 21:03 ]
Hozzászólás témája:	Re: Simple Swear Filter
Egy dolog lemaradt a leírásból, hogy a plugin FENTEBB legyen, mint a chat pluginunk.

Szerző:	*GrafitY* [ 2016.04.28. 19:43 ]
Hozzászólás témája:	Re: Simple Swear Filter
És nem írja ki 2x, ha van bent másik chat plugin? (esetemben iChat)

Szerző:	mforce [ 2016.04.28. 20:16 ]
Hozzászólás témája:	Re: Simple Swear Filter
Látsz ilyet a leírásban? Nem, nem írja ki 2x.

Szerző:	*GrafitY* [ 2016.04.28. 20:36 ]
Hozzászólás témája:	Re: Simple Swear Filter
mforce írta: Látsz ilyet a leírásban? Nem, nem írja ki 2x. Köszi!

Szerző:	mforce [ 2016.04.28. 20:44 ]
Hozzászólás témája:	Re: Simple Swear Filter
chatre íráskor leellenőrzi tartalmaz-e a szöveg tiltott fájlban szereplő szöveget, Ha igen, akkor a definiálás szerint cselekszik (vagy kicseréli -okra a karaktereket, vagy eltünteti a begépelt chatszöveget) Ha -okra cserélte, akkor újraküldi a chatre a szöveget szerveroldalról, de játékost "emulálva". https://www.amxmodx.org/api/amxmodx/engclient_cmd Aztán az eredeti szöveget a return PLUGIN_HANDLED;-el nem engedi ki chatre. Ha nem talált a fájlban szereplő tiltott szöveget, akkor nem törődik semmivel, eszik zsemlét kiflivel.

Szerző:	regener [ 2016.05.12. 19:59 ]
Hozzászólás témája:	Re: Simple Swear Filter
Tehát lényegében egybeírtál 2 már fentlévő plugint. Káromkodás átíró! Káromkodás Szűrő

Szerző:	SmaCk [ 2016.05.12. 21:48 ]
Hozzászólás témája:	Re: Simple Swear Filter
regener írta: Tehát lényegében egybeírtál 2 már fentlévő plugint. Káromkodás átíró! Káromkodás Szűrő Amit ő csinál az mindig jobb, újat már ő sem tud csinálni, valamivel muszáj eltölteni a szabadidejét..

Szerző:	mforce [ 2016.05.12. 22:06 ]
Hozzászólás témája:	Re: Simple Swear Filter
regener írta: Tehát lényegében egybeírtál 2 már fentlévő plugint. Káromkodás átíró! Káromkodás Szűrő végülis a felesleges while ciklusos összevisszaság, meg a minden chatre írásnál fájl olvasós valami tökre hasonlít erre. JA NEM!

Oldal: 1 / 2	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/