hlmod.hu :: Invis

hlmod.hu https://hlmod.hu/

Invis https://hlmod.hu/viewtopic.php?f=101&t=25972	Oldal: 1 / 1

Szerző: exodus [ 2016.08.23. 21:16 ]

Hozzászólás témája: Invis

Plugin Neve:	Invis	Plugint készitette:	Ismeretlen
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	6almasok

Sziasztok.

Beszeretnék nektek mutatni egy nagyon hasznos plugint.

Leírás:

A plugin lényege, hogy elrejtheted a víz textúrákat és a csapattársaidat, tehát nem fogod látni őket, igy nemkell egy pillanatot se gondolnunk arra, hogy csapattársunkat látjuk vagy ellenfelünket.

Működése:

Chatbe: /invis - Erre a parancsra jön elő a menü.

Alap esetben kivan kapcsolva mind 2 funkció, persze ez ezeknél a soroknál állítható:

Kód: [Egész kijelölése] [Mutatás/Eltüntetés]

g_bPlayerInvisible[id] = false; //false helyére írd: true | csapattársaid elrejtésére szolgál
g_bWaterInvisible[id] = false; //false helyére írd: true | víz textúrák elrejtésére szolgál

GeSHi © Codebox Plus

Telepítés:

invismenu.sma >> Lefordítjuk amxx-re
invismenu.amxx >> addons/amxmodx/plugins
Majd beírjuk a plugin.ini-be, hogy: invismenu.amxx

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <hamsandwich>

new const PLUGIN[] = "Invis Menu"
new const VERSION[] = "1.1"
new const AUTHOR[] = "Ismeretlen"

#define MAX_ENTITYS 900+15*32

new bool:g_bPlayerInvisible[33];
new bool:g_bWaterInvisible[33];

new bool:g_bWaterEntity[MAX_ENTITYS];
new bool:g_bWaterFound;

new g_iSpectatedId[33];

public plugin_init( )
{
    register_plugin(PLUGIN,VERSION,AUTHOR);
    
    register_clcmd( "say /invis", "menuInvisDisplay" );
    register_menucmd( register_menuid( "\yInvis Menu^n^n" ), 1023, "menuInvisAction" );
    
    register_forward( FM_AddToFullPack, "fwdAddToFullPack_Post", 1 );
    RegisterHam( Ham_Spawn, "player", "hamSpawnPlayer_Post", 1 );
    
    register_event( "SpecHealth2", "eventSpecHealth2", "bd" );
}

public plugin_cfg( )
{
    new ent = -1;
    while( ( ent = find_ent_by_class( ent, "func_water" ) ) != 0 )
    {
        
        if( !g_bWaterFound )
        {
            g_bWaterFound = true;
        }

g_bWaterEntity[ent] = true;
    }
    
    ent = -1;
    while( ( ent = find_ent_by_class( ent, "func_illusionary" ) ) != 0 )
    {
        if( pev( ent, pev_skin ) ==  CONTENTS_WATER )
        {
            if( !g_bWaterFound )
            {
                g_bWaterFound = true;
            }
    
            g_bWaterEntity[ent] = true;
        }
    }
    
    ent = -1;
    while( ( ent = find_ent_by_class( ent, "func_conveyor" ) ) != 0 )
    {
        if( pev( ent, pev_spawnflags ) == 3 )
        {
            if( !g_bWaterFound )
            {
                g_bWaterFound = true;
            }
    
            g_bWaterEntity[ent] = true;
        }
    }
}

public fwdAddToFullPack_Post( es_handle, e, ent, host, hostflags, player, pset )
{
    if( player && g_bPlayerInvisible[host] && host != ent && ent != g_iSpectatedId[host] && get_user_team(host) == get_user_team(ent) )
    {
        static const Float:corner[8][3] = 
        {
            { -4096.0, -4096.0, -4096.0 },
            { -4096.0, -4096.0, 4096.0 },
            { -4096.0, 4096.0, -4096.0 },
            { -4096.0, 4096.0, 4096.0 },
            { 4096.0, -4096.0, -4096.0 },
            { 4096.0, -4096.0, 4096.0 },
            { 4096.0, 4096.0, -4096.0 },
            { 4096.0, 4096.0, 4096.0 }
        };
        
        static const Float:map_distance = 7094.480108;
        
        static Float:origin[3];
        get_es( es_handle, ES_Origin, origin );
        
        static i;
        while( get_distance_f( origin, corner[i] ) > map_distance )
        { 
            if( ++i >= sizeof( corner ) )
            {
                i = 0;
            }
        }
        
        set_es( es_handle, ES_Origin, corner[i] );
        set_es( es_handle, ES_Effects, get_es( es_handle, ES_Effects ) | EF_NODRAW );
    }
    else if( g_bWaterInvisible[host] && g_bWaterEntity[ent])
    {
        set_es( es_handle, ES_Effects, get_es( es_handle, ES_Effects ) | EF_NODRAW );
    }
}

public hamSpawnPlayer_Post( id )
{
    g_iSpectatedId[id] = 0;
}

public eventSpecHealth2( id )
{
    g_iSpectatedId[id] = read_data( 2 );
}

public menuInvisDisplay( id )
{
    static menu[256];

new len = formatex( menu, 255, "\yInvis Menu^n^n" );
    
    len += formatex( menu[len], 255 - len, "\r1. \wJatekosok: %s^n", g_bPlayerInvisible[id] ? "Lathatatlan" : "Lathato" );
    
    if( g_bWaterFound )
    {
        len += formatex( menu[len], 255 - len, "\r2. \wViz: %s^n", g_bWaterInvisible[id] ? "Lathatatlan" : "Lathato" );
    }
     else
    {
        len += formatex( menu[len], 255 - len, "\r2. \wViz: Nem talalhato viz textura ezen a palyan!^n" );
    }

len += formatex( menu[len], 255 - len, "^n\r0. \wKilepes" );
    
    show_menu( id, ( 1<<0 | 1<<1 | 1<<9 ), menu, -1 );
        
    return PLUGIN_HANDLED;
}

public menuInvisAction( id, key )
{
    switch( key )
    {
        case 0:
        {
            g_bPlayerInvisible[id] = !g_bPlayerInvisible[id];
            menuInvisDisplay( id );
        }
        case 1:
        {
            if( g_bWaterFound )
            {
                g_bWaterInvisible[id] = !g_bWaterInvisible[id];
            }
            
            menuInvisDisplay( id );
        }
        case 9: show_menu( id, 0, "" );
    }
}

public client_connect( id )
{
    g_bPlayerInvisible[id] = false;
    g_bWaterInvisible[id] = false;
    g_iSpectatedId[id] = 0;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	D34D [ 2016.08.23. 21:18 ]
Hozzászólás témája:	Re: Invis
Ez nagyon jó ötlett.

Szerző:	6almasok [ 2016.08.23. 22:00 ]
Hozzászólás témája:	Re: Invis
Authort írd át az eredetire különben kuka + normálisabb plugin nevet is adhatnál

Szerző:	exodus [ 2016.08.23. 22:15 ]
Hozzászólás témája:	Re: Invis
6almasok írta: Authort írd át az eredetire különben kuka + normálisabb plugin nevet is adhatnál Nincs eredeti author invis pluginoknál, szinte seholsem elérhető .sma-ban, ez is egy hibás darab volt, javítottam. De ha kell írok bele névtelenül.

Szerző:	D34D [ 2016.08.23. 22:24 ]
Hozzászólás témája:	Re: Invis
Rendes neve, Invisible

Szerző:	exodus [ 2016.08.23. 22:35 ]
Hozzászólás témája:	Re: Invis
D34D írta: Rendes neve, Invisible Csak magyar verzió nem érhető el sehol mert amxx-be van. Gondoltam feltöltöm ha már én már nem használom

Szerző:	D34D [ 2016.08.23. 22:36 ]
Hozzászólás témája:	Re: Invis
Szerintem jobban hangzik, ez a név Invisible

Szerző:	exodus [ 2016.08.23. 22:38 ]
Hozzászólás témája:	Re: Invis
D34D írta: Szerintem jobban hangzik, ez a név Invisible invis-nek hívják, minden külföldi nagy surf szerveren fenntvan.

Szerző:	6almasok [ 2016.08.23. 22:40 ]
Hozzászólás témája:	Re: Invis
exodus írta: 6almasok írta: Authort írd át az eredetire különben kuka + normálisabb plugin nevet is adhatnál Nincs eredeti author invis pluginoknál, szinte seholsem elérhető .sma-ban, ez is egy hibás darab volt, javítottam. De ha kell írok bele névtelenül. Off Topic Ha nincs eredi author akkor se írod oda a te neved mivel nem te készítetted a plugint. Helyére unknow vagy ismeretlen szót írj.

Szerző:	exodus [ 2016.08.23. 22:46 ]
Hozzászólás témája:	Re: Invis
6almasok írta: exodus írta: 6almasok írta: Authort írd át az eredetire különben kuka + normálisabb plugin nevet is adhatnál Nincs eredeti author invis pluginoknál, szinte seholsem elérhető .sma-ban, ez is egy hibás darab volt, javítottam. De ha kell írok bele névtelenül. Off Topic Ha nincs eredi author akkor se írod oda a te neved mivel nem te készítetted a plugint. Helyére unknow vagy ismeretlen szót írj. JAVÍTVA, FRISSÍTVE! AUTHOR = Ismeretlen

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/