hlmod.hu :: Nade Semiclip v2.4

hlmod.hu https://hlmod.hu/

Nade Semiclip v2.4 https://hlmod.hu/viewtopic.php?f=101&t=29023	Oldal: 1 / 1

Szerző:

Dooz [ 2018.05.29. 13:07 ]

Hozzászólás témája:

Nade Semiclip v2.4

Plugin Neve:	Nade Semiclip v2.4	Plugint készitette:	JustGo
Játék:	Counter-Strike	Kategória:	Általános célú
Eredeti link:	Megnézem	Jóváhagyó:	6almasok

Nade Semiclip v2.4

Leírás:
Egy egyszerü plugin, amely segítségével engedélyezni tudod, hogy az eldobott gránát át tudjon-e menni a csapattárson/ellenségen.

Beállítások:
nade_semiclip 0: Senki sem megy át a gránát.
nade_semiclip 1: Csak a csapattárson megy át a gránát. (Ez van alapból beállítva)
nade_semiclip 2: Mindenkin átmegy a gránát.

Fontos:
Ha módosítod a nade_semiclip értékét, akkor csak a következő körben fog érvénybe lépni a változás.

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "Nade Semiclip"
#define VERSION "2.4"
#define AUTHOR "JustGo"

#define OFFSET_TEAM	114
#define fm_get_user_team(%1)	get_pdata_int(%1,OFFSET_TEAM)
#define is_grenade_c4(%1)	(get_pdata_int(%1, 96) & (1<<8)) // 96 is the C4 offset

#define SEMI_CLIP_DISTANCE 100.0

new cvar_nade_semiclip, g_nade_semiclip

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
	
	RegisterHam(Ham_Think, "grenade", "Think_Grenade")
	
	register_forward(FM_SetModel, "SetModel")
	register_forward(FM_ShouldCollide, "ShouldCollide")
	
	cvar_nade_semiclip = register_cvar( "nade_semiclip", "1" )
}

public event_round_start()
{
	g_nade_semiclip = get_pcvar_num( cvar_nade_semiclip )
}

// Grenade Think Forward
public Think_Grenade(entity)
{
	if(!g_nade_semiclip)
		return HAM_IGNORED
	
	if(!pev_valid(entity))
		return HAM_IGNORED
	
	if(is_grenade_c4(entity))
		return HAM_IGNORED
	
	static Float:dmgtime
	pev(entity, pev_dmgtime, dmgtime)
	
	if(dmgtime <= get_gametime())
		set_pev(entity, pev_owner,pev(entity,pev_iuser2)); // fix for other plugin that gets flasher name or stuff like that.
	
	return HAM_IGNORED;
}

public SetModel(iEntity, const Model[])
{
	if(!g_nade_semiclip)
		return FMRES_IGNORED
		
	if(!is_grenade(iEntity))
		return FMRES_IGNORED
		
	static id; id = pev(iEntity, pev_owner)
	if(!pev(iEntity,pev_iuser2))  
	{
		set_pev(iEntity,pev_iuser2,id) //remeber the real nade owner
		set_pev(iEntity,pev_iuser1,fm_get_user_team(id)) // remeber the nade owner team
	}
		
	return FMRES_IGNORED
}

public ShouldCollide(playerindex, entindex)
{
	if(!g_nade_semiclip)
		return FMRES_IGNORED
		
	if(!is_user_alive(playerindex) || !is_grenade(entindex))
		return FMRES_IGNORED
		
	// Get damage time of grenade
	static Float:dmgtime
	pev(entindex, pev_dmgtime, dmgtime)
		
	if(dmgtime <= get_gametime())
		return FMRES_IGNORED
	
	if(close_enough(playerindex,entindex))
	{		
		if(g_nade_semiclip == 1 && (fm_get_user_team( playerindex ) != pev(entindex,pev_iuser1)))
			return FMRES_IGNORED
		
		set_pev(entindex,pev_owner,playerindex)
	}

return FMRES_IGNORED
}

is_grenade(iEntity)
{
	if( !pev_valid(iEntity) )
		return 0
	
	static class[9] 
	pev(iEntity, pev_classname, class, charsmax(class)) 
	if( !equal(class, "grenade") )
		return 0
	
	if (is_grenade_c4(iEntity))
		return 0
	
	return 1
}

public bool:close_enough(ent1, ent2)
{
    static Float:origin[3], Float:origin2[3]
    
    pev(ent1, pev_origin, origin )
    pev(ent2, pev_origin, origin2 )
    
    if( get_distance_f( origin, origin2 ) <= SEMI_CLIP_DISTANCE )
        return true

return false    
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	krisz52 [ 2018.12.18. 20:43 ]
Hozzászólás témája:	Re: Nade Semiclip v2.4
HIBA BELE RAGADOK A MÁSIKBA

Szerző:	norbee.16 [ 2018.12.19. 21:12 ]
Hozzászólás témája:	Re: Nade Semiclip v2.4
Ezt elég értelmetlenül írtad le/fogalmaztad meg. Helyes megfogalmazás. Bent van a szerveren a semiclip és át szeretném dobni a társamon a gránátot, de meg akad benne. Viszont ha megnézed alliedmoddersen(mondhatni hivatalos beszerzési helyén) akkor talán a leírásban vagy valamelyik kommentben ez fel is van tüntetve, de tudomásom szerint van egy bugfixed verzió valahol.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/