/* Script generated by Pawn Studio */
 
#include <amxmodx>
#include <fakemeta>
 
#define PLUGIN	"hideNotUsed"
#define AUTHOR	"DarkGL"
#define VERSION	"1.0"
 
forward bb_round_started();
 
new pCvarTime ,
	Float: fAmount	=	255.0 ,
	Float: fOffset	=	0.0 ;
 
public plugin_init(){
 
	register_plugin(PLUGIN, VERSION, AUTHOR)
 
	pCvarTime	=	register_cvar( "hideTime" , "4.0" );
}
 
public bb_round_started(){
 
	fAmount	=	255.0;
 
	fOffset	=	fAmount / ( get_pcvar_float( pCvarTime ) * 10.0 ) ;
 
	setBlocks( fAmount , .reset = true );
 
	set_task( 0.1 , "hideAll" );
}
 
public hideAll(){
	if( fAmount <= 0.0 ){
 
		setBlocks( fAmount , .changeOrigin = true );
 
		return ;
	}
 
	fAmount	-=	fOffset;
 
	setBlocks( fAmount );
 
	set_task( 0.1 , "hideAll" );
}
 
setBlocks( Float: fAmount , bool: changeOrigin = false , bool: reset = false ){
 
	new szTarget[ 16 ] ,
		iEnt ;
 
	while( ( iEnt = engfunc( EngFunc_FindEntityByString , iEnt , "classname" , "func_wall" ) ) != 0 ){
 
		if( !pev_valid( iEnt ) ){
			continue;
		}
 
		pev( iEnt , pev_targetname , szTarget , charsmax( szTarget ) );
 
		if( equal( szTarget , "ignore" ) || equal( szTarget , "barrier" ) || bb_is_used_block( iEnt ) ){
			continue;
		}
 
		if( reset ){
			set_pev( iEnt , pev_rendermode , kRenderNormal );
			set_pev( iEnt , pev_renderamt , 255.0 );
		}
		else if( !changeOrigin ){
			set_pev( iEnt , pev_rendermode , kRenderTransTexture );
			set_pev( iEnt , pev_renderamt , fAmount );
		}
 
		if( changeOrigin ){
			engfunc( EngFunc_SetOrigin , iEnt , { 9999.0 , 9999.0 , 9999.0 } );
		}
 
	}
}
 
bool: bb_is_used_block( iEnt ){
	return pev( iEnt , pev_iuser4 ) != 0;
}