hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.05.24. 13:52

Megválaszolatlan témák | Aktív témák



» » »


Navigáció
Jelenlévő felhasználók

Jelenleg 475 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 475 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  Oldal: 1 / 1
  [ 3 hozzászólás ] 
  Nyomtatóbarát verzió | Barát értesítése e-mailben Előző téma | Következő téma 
Szerző Üzenet
pixxa112
 Hozzászólás témája: Furien
HozzászólásElküldve: 2013.04.15. 00:07 
Offline
Őskövület
Avatar

Csatlakozott: 2011.12.28. 00:35
Hozzászólások: 2736
Megköszönt másnak: 56 alkalommal
Megköszönték neki: 275 alkalommal
Hali.

Valaki ebből a pluginból ki tudná szedni, hogy amit meg kérdez csapat választás után azt ne kérdezze.

SMA Forráskód: [ Mindet kijelol ]
  1. [en]
  2. FURIEN_MENU_CVAR:
  3. \rFuriens Cvars\w :^n^n
  4. To take full advantage of Furien Mod,^n
  5. you must allow server to change your speed settings.^n
  6. Do you accept ?


SMA Forráskód: [ Mindet kijelol ]
  1. #include <amxmodx>
  2. #include <cstrike>
  3. #include <engine>
  4. #include <fun>
  5. #include <fakemeta>
  6. #include <hamsandwich>
  7.  
  8. #include "furien.inc"
  9.  
  10. #define MAX_PLAYERS 32
  11.  
  12. #define Ham_Player_ResetMaxSpeed Ham_Item_PreFrame
  13.  
  14. new g_iMaxPlayers
  15. #define FIRST_PLAYER_ID	1
  16. #define IsPlayer(%1)	( FIRST_PLAYER_ID <= %1 <= g_iMaxPlayers )
  17.  
  18. new CsTeams:g_iFuriensTeam = CS_TEAM_T
  19.  
  20. // players offsets
  21. #define XTRA_OFS_PLAYER 5
  22. #define m_iAccount 115
  23. #define cs_set_money_value(%1,%2)	set_pdata_int(%1, m_iAccount, %2, XTRA_OFS_PLAYER)
  24.  
  25. // "weaponbox" offsets
  26. #define XO_WEAPONBOX				4
  27. #define m_rgpPlayerItems_wpnbx_Slot5	39
  28. #define IsWeaponBoxC4(%1)	( get_pdata_cbase(%1, m_rgpPlayerItems_wpnbx_Slot5, XO_WEAPONBOX) > 0 )
  29.  
  30. new g_bShouldAnswerMenu, g_bCanModifyCvars
  31. #define MarkUserSeeMenu(%1)	g_bShouldAnswerMenu |= 1<<(%1&31)
  32. #define ClearUserSeeMenu(%1)	g_bShouldAnswerMenu &= ~(1<<(%1&31))
  33. #define ShouldUserSeeMenu(%1)	g_bShouldAnswerMenu & 1<<(%1&31)
  34.  
  35. #define MarkUserCvars(%1)	g_bCanModifyCvars |= 1<<(%1&31)
  36. #define ClearUserCvars(%1)	g_bCanModifyCvars &= ~(1<<(%1&31))
  37. #define CanUserCvars(%1)		g_bCanModifyCvars & 1<<(%1&31)
  38.  
  39. const CVARS_MENU_KEYS = (1<<0)|(1<<1)
  40.  
  41. new g_iFurienTeamChangeForward
  42.  
  43. new g_iFurienRoundRestartForward, bool:g_bRestarting
  44.  
  45. new Float:g_flFurienGravity = 0.375
  46. new g_iInvisFactor = 1
  47. new Float:g_flMaxSpeed = 500.0
  48. new g_iFurienReward = 1337
  49. new g_iAntiReward = 400
  50. new g_iAnnounce = 1
  51.  
  52. new bool:g_bSwitchTeam = true
  53. new bool:g_bSwitchInProgress
  54.  
  55. new Trie:g_tPreventEntityKeyvalue
  56. new g_iPickUp = 2
  57.  
  58. new g_szSpeedCommand[128]
  59.  
  60. new g_szFurienWinSound[64]
  61. new g_szAntiWinSound[64]
  62.  
  63. new g_szGameDescription[32]
  64.  
  65. new g_bitBombPlant
  66.  
  67. new g_iNewMoney
  68. new g_iMsgHookMoney
  69.  
  70. new g_iTextMsg, g_iMoney
  71.  
  72. new HamHook:g_iHhTakeDamage
  73.  
  74. public plugin_natives()
  75. {
  76. 	register_library("furien")
  77. 	register_native("furien_get_user_team", "fr_get_user_team")
  78. }
  79.  
  80. public plugin_precache()
  81. {
  82. 	if( !ReadCfgFile() )
  83. 	{
  84. 		log_amx("Configuration file doesn't exist !!")
  85. 	}
  86. }
  87.  
  88. public plugin_init()
  89. {
  90. 	register_plugin("Furiens", FURIEN_VERSION, "ConnorMcLeod")
  91.  
  92. 	register_dictionary("common.txt")
  93. 	register_dictionary("furiens.txt")
  94.  
  95. 	new pCvar = register_cvar("furien_version", FURIEN_VERSION, FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_SPONLY)
  96. 	set_pcvar_string(pCvar, FURIEN_VERSION)
  97.  
  98. 	register_clcmd("say ?", "A_Propos")
  99. 	register_clcmd("say_team ?", "A_Propos")
  100. 	register_clcmd("?", "A_Propos")	
  101.  
  102. 	register_menucmd(register_menuid("Furiens Cvars"), CVARS_MENU_KEYS, "CvarsMenuCallBack")
  103.  
  104. 	RegisterHam(Ham_Spawn, "player", "Player_Spawn_Post", 1)
  105. 	RegisterHam(Ham_Player_ResetMaxSpeed, "player", "Player_ResetMaxSpeed", 1)
  106.  
  107. 	register_message(get_user_msgid("SendAudio"), "Message_SendAudio")
  108.  
  109. 	new iEnt
  110. 	iEnt = create_entity("info_target")
  111. 	set_pev(iEnt, pev_classname, "check_speed")
  112. 	set_pev(iEnt, pev_nextthink, get_gametime() + 0.1)
  113. 	register_think("check_speed", "Set_Furiens_Visibility")
  114.  
  115. 	iEnt = create_entity("info_target")
  116. 	set_pev(iEnt, pev_classname, "check_cvars")
  117. 	set_pev(iEnt, pev_nextthink, get_gametime() + 10.0)
  118. 	register_think("check_cvars", "Check_Players_Cvars")
  119.  
  120. 	g_iFurienTeamChangeForward = CreateMultiForward("furien_team_change", ET_IGNORE, FP_CELL)
  121.  
  122. 	register_event("TextMsg", "Event_TextMsg_Restart", "a", "2&#Game_C", "2&#Game_w")
  123. 	register_event("HLTV", "Event_HLTV_New_Round", "a", "1=0", "2=0")
  124. 	g_iFurienRoundRestartForward = CreateMultiForward("furien_round_restart", ET_IGNORE)
  125.  
  126. 	register_event("DeathMsg", "Event_DeathMsg", "a")
  127.  
  128. 	if( get_cvar_float("sv_maxspeed") < g_flMaxSpeed )
  129. 	{
  130. 		set_cvar_float("sv_maxspeed", g_flMaxSpeed)
  131. 	}
  132.  
  133. 	formatex(g_szSpeedCommand, charsmax(g_szSpeedCommand), 
  134. 			";cl_forwardspeed %.1f;cl_sidespeed %.1f;cl_backspeed %.1f",
  135. 							g_flMaxSpeed, g_flMaxSpeed, g_flMaxSpeed)
  136.  
  137. 	g_iMaxPlayers = get_maxplayers()
  138. 	g_iTextMsg = get_user_msgid("TextMsg")
  139. 	g_iMoney = get_user_msgid("Money")
  140. }
  141.  
  142. ReadCfgFile()
  143. {
  144. 	new szConfigFile[128]
  145. 	get_localinfo("amxx_configsdir", szConfigFile, charsmax(szConfigFile))
  146. 	format(szConfigFile, charsmax(szConfigFile), "%s/furien/furien.ini", szConfigFile);
  147.  
  148. 	new fp = fopen(szConfigFile, "rt")
  149. 	if( !fp )
  150. 	{
  151. 		return 0
  152. 	}
  153.  
  154. 	new szDatas[96], szKey[16], szValue[64]
  155. 	while( !feof(fp) )
  156. 	{
  157. 		fgets(fp, szDatas, charsmax(szDatas))
  158. 		trim(szDatas)
  159. 		if(!szDatas[0] || szDatas[0] == ';' || szDatas[0] == '#' || (szDatas[0] == '/' && szDatas[1] == '/'))
  160. 		{
  161. 			continue
  162. 		}
  163.  
  164. 		parse(szDatas, szKey, charsmax(szKey), szValue, charsmax(szValue))
  165.  
  166. 		switch( szKey[0] )
  167. 		{
  168. 			case 'B':
  169. 			{
  170. 				switch( szKey[1] )
  171. 				{
  172. 					case 'U':
  173. 					{
  174. 						if( equal(szKey, "BUY") )
  175. 						{
  176. 							switch( clamp(str_to_num(szValue), 0, 1) )
  177. 							{
  178. 								case 0:
  179. 								{
  180. 									new iEnt
  181.  
  182. 									g_tPreventEntityKeyvalue = TrieCreate()
  183. 									TrieSetCell(g_tPreventEntityKeyvalue, "player_weaponstrip", 1)
  184. 									TrieSetCell(g_tPreventEntityKeyvalue, "game_player_equip", 1)
  185. 									TrieSetCell(g_tPreventEntityKeyvalue, "info_map_parameters", 1)
  186.  
  187. 									iEnt = create_entity("info_map_parameters")
  188. 									DispatchKeyValue(iEnt, "buying", "3")
  189. 									DispatchSpawn(iEnt)
  190.  
  191. 									register_buy_cmd()
  192. 								}
  193. 							}
  194. 						}
  195. 					}
  196. 					case 'O':
  197. 					{
  198. 						if( equal(szKey, "BOMB_PLANT") )
  199. 						{
  200. 							g_bitBombPlant = clamp(str_to_num(szValue), 0, 3)
  201. 							if( g_bitBombPlant != 3 )
  202. 							{
  203. 								RegisterHam(Ham_AddPlayerItem, "player", "Player_AddPlayerItem")
  204. 							}
  205. 						}
  206. 					}
  207. 				}
  208. 			}
  209. 			case 'F':
  210. 			{
  211. 				if( equal(szKey, "FURIEN_ANNOUNCE") )
  212. 				{
  213. 					g_iAnnounce = str_to_num(szValue)
  214. 				}
  215. 			}
  216. 			case 'G':
  217. 			{
  218. 				switch( szKey[1] )
  219. 				{
  220. 					case 'A':
  221. 					{
  222. 						if( equal(szKey, "GAMENAME") )
  223. 						{
  224. 							replace(szValue, charsmax(szValue), "%v", FURIEN_VERSION)
  225. 							copy(g_szGameDescription, charsmax(g_szGameDescription), szValue)
  226. 							register_forward(FM_GetGameDescription, "GetGameDescription")
  227. 						}
  228. 					}
  229. 					case 'R':
  230. 					{
  231. 						if( equal(szKey, "GRAVITY") )
  232. 						{
  233. 							g_flFurienGravity = floatclamp(str_to_float(szValue), 0.0125, 1.0)
  234. 						}
  235. 					}
  236. 				}
  237. 			}
  238. 			case 'I':
  239. 			{
  240. 				if( equal(szKey, "INVIS_FACTOR") )
  241. 				{
  242. 					g_iInvisFactor = clamp(str_to_num(szValue), 1, 4)
  243. 				}
  244. 			}
  245. 			case 'K':
  246. 			{
  247. 				switch( szKey[5] )
  248. 				{
  249. 					case 'A':
  250. 					{
  251. 						if( equal(szKey, "KILL_ANTI_REWARD") )
  252. 						{
  253. 							g_iAntiReward = str_to_num(szValue)
  254. 						}
  255. 					}
  256. 					case 'F':
  257. 					{
  258. 						if( equal(szKey, "KILL_FURIEN_REWARD") )
  259. 						{
  260. 							g_iFurienReward = str_to_num(szValue)
  261. 						}
  262. 					}
  263. 				}
  264. 			}
  265. 			case 'M':
  266. 			{
  267. 				if( equal(szKey, "MAXSPEED") )
  268. 				{
  269. 					g_flMaxSpeed = floatclamp(str_to_float(szValue), 100.0, 2000.0)
  270. 				}
  271. 			}
  272. 			case 'P':
  273. 			{
  274. 				if( equal(szKey, "PICK_UP") )
  275. 				{
  276. 					g_iPickUp = clamp(str_to_num(szValue), 0, 3)
  277. 					switch( g_iPickUp )
  278. 					{
  279. 						case 0,1,2:
  280. 						{
  281. 							RegisterHam(Ham_Touch, "weaponbox", "CWeaponBox_Touch")
  282. 							RegisterHam(Ham_Touch, "armoury_entity", "GroundWeapon_Touch")
  283. 							RegisterHam(Ham_Touch, "weapon_shield", "GroundWeapon_Touch")
  284. 						}
  285. 					}
  286. 				}
  287. 			}
  288. 			case 'S':
  289. 			{
  290. 				if( equal(szKey, "SWITCH_TEAMS") )
  291. 				{
  292. 					g_bSwitchTeam = !!clamp(str_to_num(szValue), 0, 1)
  293. 					if( g_bSwitchTeam )
  294. 					{
  295. 						g_iHhTakeDamage = RegisterHam(Ham_TakeDamage, "player", "Player_TakeDamage")
  296. 						DisableHamForward( g_iHhTakeDamage )
  297. 					}
  298. 				}
  299. 			}
  300. 			case 'W':
  301. 			{
  302. 				if( equal(szKey, "WIN_SOUND_", 10) )
  303. 				{
  304. 					new szFullPath[128]
  305. 					switch(szKey[10])
  306. 					{
  307. 						case 'F':
  308. 						{
  309. 							formatex(szFullPath, charsmax(szFullPath), "sound/%s", szValue)
  310. 							if( file_exists(szFullPath) )
  311. 							{
  312. 								copy(g_szFurienWinSound, charsmax(g_szFurienWinSound), szValue)
  313. 								precache_sound(szValue)
  314. 							}
  315. 						}
  316. 						case 'A':
  317. 						{
  318. 							formatex(szFullPath, charsmax(szFullPath), "sound/%s", szValue)
  319. 							if( file_exists(szFullPath) )
  320. 							{
  321. 								copy(g_szAntiWinSound, charsmax(g_szAntiWinSound), szValue)
  322. 								precache_sound(szValue)
  323. 							}
  324. 						}
  325. 					}
  326. 				}
  327. 			}
  328. 		}
  329. 	}
  330. 	fclose( fp )
  331.  
  332. 	return 1
  333. }
  334.  
  335. public GetGameDescription()
  336. {
  337. 	forward_return(FMV_STRING, g_szGameDescription)
  338. 	return FMRES_SUPERCEDE
  339. }
  340.  
  341. public Event_TextMsg_Restart()
  342. {
  343. 	g_bRestarting = true
  344. }
  345.  
  346. public Event_HLTV_New_Round()
  347. {
  348. 	if( g_bRestarting )
  349. 	{
  350. 		g_bRestarting = false
  351. 		new iRet
  352. 		ExecuteForward(g_iFurienRoundRestartForward, iRet)
  353. 	}
  354.  
  355. 	if( g_bSwitchInProgress )
  356. 	{
  357. 		g_bSwitchInProgress = false
  358. 		DisableHamForward( g_iHhTakeDamage )
  359. 	}
  360. }
  361.  
  362. public GroundWeapon_Touch(iWeapon, id)
  363. {
  364. 	if( IsPlayer(id) )
  365. 	{
  366. 		if( !g_iPickUp )
  367. 		{
  368. 			remove_entity(iWeapon)
  369. 			return HAM_SUPERCEDE
  370. 		}
  371.  
  372. 		if( !is_user_alive(id) )
  373. 		{
  374. 			return HAM_SUPERCEDE
  375. 		}
  376.  
  377. 		new iTeam = __get_user_team(id)
  378. 		if(	( iTeam == -1 )
  379. 		||	(iTeam == Furien && g_iPickUp != 1)
  380. 		||	(iTeam == AntiFurien && g_iPickUp != 2)	)
  381. 		{
  382. 			return HAM_SUPERCEDE
  383. 		}
  384. 	}
  385. 	return HAM_IGNORED
  386. }
  387.  
  388. public CWeaponBox_Touch(iWeaponBox, id)
  389. {
  390. 	if( IsPlayer(id) )
  391. 	{
  392. 		if( !is_user_alive(id) )
  393. 		{
  394. 			return HAM_SUPERCEDE
  395. 		}
  396.  
  397. 		if( IsWeaponBoxC4(iWeaponBox) )
  398. 		{
  399. 			return HAM_IGNORED
  400. 		}
  401.  
  402. 		if( !g_iPickUp )
  403. 		{
  404. 			remove_entity(iWeaponBox)
  405. 			return HAM_SUPERCEDE
  406. 		}
  407.  
  408. 		new iTeam = __get_user_team(id)
  409. 		if(	( iTeam == -1 )
  410. 		||	(iTeam == Furien && g_iPickUp != 1)
  411. 		||	(iTeam == AntiFurien && g_iPickUp != 2)	)
  412. 		{
  413. 			return HAM_SUPERCEDE
  414. 		}
  415. 	}
  416. 	return HAM_IGNORED
  417. }
  418.  
  419. register_buy_cmd()
  420. {
  421. 	register_clcmd("buy", "ClientCommand_Buy")
  422. 	register_clcmd("bUy", "ClientCommand_Buy")
  423. 	register_clcmd("buY", "ClientCommand_Buy")
  424. 	register_clcmd("bUY", "ClientCommand_Buy")
  425. 	register_clcmd("Buy", "ClientCommand_Buy")
  426. 	register_clcmd("BUy", "ClientCommand_Buy")
  427. 	register_clcmd("BuY", "ClientCommand_Buy")
  428. 	register_clcmd("BUY", "ClientCommand_Buy")
  429. }
  430.  
  431. public ClientCommand_Buy(id)
  432. {
  433. 	return PLUGIN_HANDLED_MAIN
  434. }
  435.  
  436. public pfn_keyvalue( iEnt ) 
  437. {
  438. 	if( g_tPreventEntityKeyvalue )
  439. 	{
  440. 		new szClassName[32], szCrap[2]
  441. 		copy_keyvalue(szClassName, charsmax(szClassName), szCrap, charsmax(szCrap), szCrap, charsmax(szCrap)) 
  442. 		if( TrieKeyExists(g_tPreventEntityKeyvalue, szClassName) )
  443. 		{
  444. 			remove_entity(iEnt)
  445. 			return PLUGIN_HANDLED
  446. 		}
  447. 	}
  448. 	return PLUGIN_CONTINUE
  449. }
  450.  
  451. public plugin_cfg()
  452. {
  453. 	if( g_tPreventEntityKeyvalue )
  454. 	{
  455. 		TrieDestroy(g_tPreventEntityKeyvalue)
  456. 		set_cvar_float("sv_restart", 1.0)
  457. 	}
  458. }
  459.  
  460. public fr_get_user_team(/*iPlugin, iParams*/)
  461. {
  462. 	return __get_user_team( get_param(1) )
  463. }
  464.  
  465. __get_user_team(id)
  466. {
  467. 	new CsTeams:iTeam = cs_get_user_team(id)
  468. 	if( CS_TEAM_T <= iTeam <= CS_TEAM_CT )
  469. 	{
  470. 		if( iTeam == g_iFuriensTeam )
  471. 		{
  472. 			return Furien
  473. 		}
  474. 		return AntiFurien
  475. 	}
  476. 	return -1
  477. }
  478.  
  479. public client_connect(id)
  480. {
  482. 	query_client_cvar(id, "gl_clear", "Client_Cvar_Result")
  483. }
  484.  
  485. public Client_Cvar_Result(id, const szCvar[], const szValue[])
  486. {
  487. 	if( szValue[0] == 'B' )
  488. 	{
  489. 		server_cmd("kick #%d Software video mode forbidden !! Acceleration logicielle interdite !!", get_user_userid(id))
  490. 	}
  491. }
  492.  
  493. public client_putinserver( id )
  494. {
  495. 	MarkUserSeeMenu( id )
  496. 	ClearUserCvars( id )
  497.  
  498. 	if( g_iAnnounce )
  499. 	{
  500. 		set_task(random_float(11.0, 19.0), "A_Propos", id)
  501. 	}
  502. }
  503.  
  504. public Player_Spawn_Post( id )
  505. {
  506. 	if( is_user_alive(id) )
  507. 	{
  508. 		if( ShouldUserSeeMenu(id) )
  509. 		{
  510. 			ShowSpeedCvarsMenu(id)
  511. 		}
  512.  
  513. 		strip_user_weapons(id)
  514.  
  515. 		if( __get_user_team(id) == Furien )
  516. 		{
  517. 			set_user_gravity(id, g_flFurienGravity)
  518. 			set_user_footsteps(id, 1)
  519. 		}
  520. 		else
  521. 		{
  522. 			set_user_footsteps(id, 0)
  523. 			set_user_gravity(id, 1.0)
  524. 		}
  525.  
  526. 		set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)
  527. 	}
  528. }
  529.  
  530. ShowSpeedCvarsMenu(id)
  531. {
  532. 	new szMenu[256], n
  533. 	n += formatex(szMenu[n], charsmax(szMenu)-n, "%L^n", id, "FURIEN_MENU_CVAR")
  534. 	n += formatex(szMenu[n], charsmax(szMenu)-n, "^n\y1\w. %L", id, "YES")
  535. 	n += formatex(szMenu[n], charsmax(szMenu)-n, "^n\y2\w. %L", id, "NO")
  536.  
  537. 	show_menu(id, CVARS_MENU_KEYS, szMenu, -1, "Furiens Cvars")
  538. }
  539.  
  540. public CvarsMenuCallBack(id, iKey)
  541. {
  542. 	switch( iKey )
  543. 	{
  544. 		case 0:
  545. 		{
  546. 			MarkUserCvars( id )
  547. 			ClearUserSeeMenu( id )
  548. 		}
  549. 		case 1:
  550. 		{
  551. 			ClearUserCvars( id )
  552. 		}
  553. 	}
  554. 	return PLUGIN_HANDLED
  555. }
  556.  
  557. public Player_ResetMaxSpeed( id )
  558. {
  559. 	if( is_user_alive(id) && __get_user_team(id) == Furien && get_user_maxspeed(id) != 1.0 )
  560. 	{
  561. 		set_pev(id, pev_maxspeed, g_flMaxSpeed)
  562. 	}
  563. }
  564.  
  565. public Check_Players_Cvars( iEnt )
  566. {
  567. 	entity_set_float(iEnt, EV_FL_nextthink, get_gametime() + 5.0)
  568.  
  569. 	new iPlayers[MAX_PLAYERS], iNum, id
  570. 	get_players(iPlayers, iNum, "ace", g_iFuriensTeam == CS_TEAM_T ? "TERRORIST" : "CT")
  571. 	for(new i; i<iNum; i++)
  572. 	{
  573. 		id = iPlayers[i]
  574. 		if( CanUserCvars( id ) )
  575. 		{
  576. 			query_client_cvar(id, "cl_forwardspeed", "CvarResult")
  577. 			query_client_cvar(id, "cl_backspeed", "CvarResult")
  578. 			query_client_cvar(id, "cl_sidespeed", "CvarResult")
  579. 		}
  580. 	}
  581. }
  582.  
  583. public CvarResult(const id, const szCvar[], const szValue[])
  584. {
  585. 	if( CanUserCvars( id ) && is_user_connected(id) && str_to_float(szValue) < g_flMaxSpeed )
  586. 	{
  587. 		client_cmd(id, g_szSpeedCommand)
  588. 	}
  589. }
  590.  
  591. public Set_Furiens_Visibility( iEnt )
  592. {
  593. 	entity_set_float(iEnt, EV_FL_nextthink, get_gametime() + 0.1)
  594.  
  595. 	new iPlayers[MAX_PLAYERS], iNum, id, Float:fVecVelocity[3], iSpeed
  596.  
  597. 	get_players(iPlayers, iNum, "ae", g_iFuriensTeam == CS_TEAM_T ? "TERRORIST" : "CT")
  598.  
  599. 	for(new i; i<iNum; i++)
  600. 	{
  601. 		id = iPlayers[i]
  602. 		if( get_user_weapon(id) == CSW_KNIFE )
  603. 		{
  604. 			entity_get_vector(id, EV_VEC_velocity, fVecVelocity)
  605. 			iSpeed = floatround( vector_length(fVecVelocity) )
  606. 			if( iSpeed < g_iInvisFactor*255 )
  607. 			{
  608. 				set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransAlpha, iSpeed/g_iInvisFactor)
  609. 			}
  610. 			else
  611. 			{
  612. 				set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)
  613. 			}
  614. 		}
  615. 		else
  616. 		{
  617. 			set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)
  618. 		}
  619. 	}
  620. }
  621.  
  622. public Message_SendAudio(iMsgId, iMsgDest, id)
  623. {
  624. 	if( !id )
  625. 	{
  626. 		new bool:bAntiWins
  627. 		new bool:bSwitchTeams
  628. 		new szSound[14]
  629. 		get_msg_arg_string(2, szSound, charsmax(szSound))
  630. 		if( equal(szSound, "%!MRAD_ctwin") )
  631. 		{
  632. 			if( g_iFuriensTeam == CS_TEAM_T )
  633. 			{
  634. 				if( g_bSwitchTeam )
  635. 				{
  636. 					bSwitchTeams = true
  637. 					g_iFuriensTeam = CS_TEAM_CT
  638. 				}
  639. 				bAntiWins = true
  640. 			}
  641. 		}
  642. 		else if( equal(szSound, "%!MRAD_terwin") )
  643. 		{
  644. 			if( g_iFuriensTeam == CS_TEAM_CT )
  645. 			{
  646. 				if( g_bSwitchTeam )
  647. 				{
  648. 					bSwitchTeams = true
  649. 					g_iFuriensTeam = CS_TEAM_T
  650. 				}
  651. 				bAntiWins = true
  652. 			}
  653. 		}
  654. 		else
  655. 		{
  656. 			return
  657. 		}
  658.  
  659. 		if( get_msg_block(g_iTextMsg) == BLOCK_NOT )
  660. 		{
  661. 			set_msg_block(g_iTextMsg, BLOCK_ONCE)
  662. 		}
  663.  
  664. 		new iPlayers[32], iNum, iPlayer
  665. 		get_players(iPlayers, iNum)
  666. 		for(new i; i<iNum; i++)
  667. 		{
  668. 			iPlayer = iPlayers[i]
  669. 			client_print(iPlayer, print_center, "%L", iPlayer, bAntiWins ? "FURIEN_ANTI_WIN_MSG" : "FURIEN_FURIEN_WIN_MSG")
  670. 		}
  671.  
  672. 		if( bAntiWins )
  673. 		{
  674. 			if( g_szAntiWinSound[0] )
  675. 			{
  676. 				set_msg_arg_string(2, g_szAntiWinSound)
  677. 			}
  678.  
  679. 			if( bSwitchTeams )
  680. 			{
  681. 				new iRet
  682. 				ExecuteForward(g_iFurienTeamChangeForward, iRet, g_iFuriensTeam)
  683. 				g_bSwitchInProgress = true
  684. 				EnableHamForward( g_iHhTakeDamage )
  685. 			}
  686. 		}
  687. 		else
  688. 		{
  689. 			if( g_szFurienWinSound[0] )
  690. 			{
  691. 				set_msg_arg_string(2, g_szFurienWinSound)
  692. 			}
  693. 		}		
  694. 	}
  695. }
  696.  
  697. public Event_DeathMsg()
  698. {
  699. 	new iKiller = read_data(1)
  700. 	if( IsPlayer(iKiller) && is_user_connected(iKiller) )
  701. 	{
  702. 		new iVictim = read_data(2)
  703. 		if( iVictim != iKiller )
  704. 		{
  705. 			new iVicTimTeam = __get_user_team(iVictim)
  706. 			if( __get_user_team(iKiller) == iVicTimTeam )
  707. 			{
  708. 				return
  709. 			}
  710. 			g_iNewMoney = clamp
  711. 						( 
  712. 							cs_get_user_money(iKiller) + (iVicTimTeam == Furien ? g_iFurienReward : g_iAntiReward), 
  713. 							0, 
  714. 							16000
  715. 						)
  716. 			g_iMsgHookMoney = register_message(g_iMoney, "Message_Money")
  717. 		}
  718. 	}
  719. }
  720.  
  721. public Message_Money(iMsgId, iMsgDest, id)
  722. {
  723. 	unregister_message(g_iMoney, g_iMsgHookMoney)
  724. 	cs_set_money_value(id, g_iNewMoney)
  725. 	set_msg_arg_int(1, ARG_LONG, g_iNewMoney)
  726. }
  727.  
  728. public A_Propos(id)
  729. {
  730. 	if( is_user_connected(id) )
  731. 	{
  732. 		client_print(id, print_chat, "%L", id, "FURIEN_CREDIT", FURIEN_VERSION)
  733. 		client_print(id, print_console, "%L", id, "FURIEN_LINK")
  734. 	}
  735. }
  736.  
  737. public Player_AddPlayerItem(id , iWeapon)
  738. {
  739. 	if(	ExecuteHam(Ham_Item_GetWeaponPtr, iWeapon) != iWeapon
  740. 	||	cs_get_weapon_id(iWeapon) != CSW_C4	
  741. 	||	g_bitBombPlant & __get_user_team(id)	)
  742. 	{
  743. 		return HAM_IGNORED
  744. 	}
  745.  
  746. 	set_pev(iWeapon, pev_flags, pev(iWeapon, pev_flags) | FL_KILLME)
  747. 	cs_set_user_plant(id, 0)
  748. 	set_pev(id, pev_body, 0)
  749. 	SetHamReturnInteger(0)
  750. 	return HAM_SUPERCEDE
  751. }
  752.  
  753. public Player_TakeDamage() // switch teams
  754. {
  755. 	return HAM_SUPERCEDE
  756. }

_________________
****


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
HuBaBuBa
 Hozzászólás témája: Re: Furien
HozzászólásElküldve: 2013.04.15. 09:44 
Offline
Jómunkásember

Csatlakozott: 2012.01.29. 12:48
Hozzászólások: 408
Megköszönt másnak: 15 alkalommal
Megköszönték neki: 126 alkalommal
Csatolmány:
furiens.sma [17.55 KiB]
Letöltve 28 alkalommal.


A hozzászólást 2 alkalommal szerkesztették, utoljára HuBaBuBa 2013.04.15. 11:02-kor.

Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
pixxa112
 Hozzászólás témája: Re: Furien
HozzászólásElküldve: 2013.04.15. 10:34 
Offline
Őskövület
Avatar

Csatlakozott: 2011.12.28. 00:35
Hozzászólások: 2736
Megköszönt másnak: 56 alkalommal
Megköszönték neki: 275 alkalommal
HuBaBuBa írta:
Csatolmány:
furiens.sma


És azt még át tudod írni, hogy NS is fel tudjon jönni mert van egy masik furiens plugin amivel már fel tudnak jönni az NS. De ugyan úgy rá kérdez amit elöbb írtam, de ha az igenre megyek kidob a szerverből.

_________________
****


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  Oldal: 1 / 1
  [ 3 hozzászólás ] 

» » »


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 117 vendég

Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole